Adding skylander's portal emulation support

.editorconfig

@@ -0,0 +1,30 @@
+root = true
+
+[*]
+indent_size = 2
+trim_trailing_whitespace = true
+
+[*.{c,cpp,h}]
+indent_style = space
+insert_final_newline = true
+max_line_length = 100
+
+[{CMakeLists.txt,*.cmake}]
+indent_style = tab
+
+[.editorconfig]
+insert_final_newline = true
+
+[*.gradle]
+indent_size = 4
+indent_style = space
+insert_final_newline = false
+
+[*.java]
+indent_style = tab
+insert_final_newline = true
+
+[*.xml]
+indent_size = 4
+indent_style = space
+insert_final_newline = true

.gitignore

@@ -30,9 +30,14 @@ CMakeLists.txt.user
 # Ignore emacs temp files
 \#*\#
 .\#*
-# Ignore transifex configuration directory
-.tx
 # Ignore kdevelop files/dirs
 *.kdev4
 # Ignore IDEA/Clion files/dirs
 /.idea/
+/Externals/ed25519/ed25519.log
+/Externals/picojson/picojson.log
+/Source/Android/.gradle/
+/Source/Android/.idea/
+/Source/Android/build/
+/Source/Android/app/.cxx/
+/Source/Android/app/release/

.tx/config

@@ -0,0 +1,8 @@
+[main]
+host = https://www.transifex.com
+
+[ishiiruka.emulator]
+file_filter = Languages/po/<lang>.po
+source_file = Languages/po/ishiiruka.pot
+source_lang = en-US
+type = PO

AndroidSetup.md

@@ -4,17 +4,10 @@ If you'd like to contribute to the Android project, but do not currently have a
 
 ## Prerequisites
 
-* A Linux VM or host, or a Mac.
-* JDK 7 for your platform.
-* CMake
-* [Android NDK](https://developer.android.com/tools/sdk/ndk/index.html) 
-* [Android Studio](http://developer.android.com/tools/studio/index.html) **OR**
-* [Android SDK Tools](http://developer.android.com/sdk/index.html#Other) (for command-line usage)
+* [Android Studio](http://developer.android.com/tools/studio/index.html)
 
 If you downloaded Android Studio, extract it and then see [Setting up Android Studio](#setting-up-android-studio).
 
-If you instead chose to download the commoand-line SDK tools, see [Setting up the SDK Tools](#setting-up-the-sdk-tools).
-
 ## Setting up Android Studio
 
 1. Launch Android Studio, which will start a first-launch wizard.
@@ -26,12 +19,6 @@ If you instead chose to download the commoand-line SDK tools, see [Setting up th
 7. Use the SDK Manager to get necessary dependencies, as described in [Getting Dependencies](#getting-dependencies).
 8. When done, follow the steps in [Readme.md](Readme.md#installation-on-android) to compile and deploy the application.
 
-## Setting up the SDK Tools
-
-1. In `Source/Android`, create a file called `local.properties`.
-2. Add a single line: `sdk.dir=<sdk-path>`, where `<sdk-path>` is the path where you extracted the SDK Tools package.
-3. Follow the steps in [Readme.md](Readme.md#installation-on-android) to compile and deploy the application.
-
 ## Executing Gradle Tasks
 
 In Android Studio, you can find a list of possible Gradle tasks in a tray at the top right of the screen:
@@ -50,19 +37,14 @@ For command-line users, any task may be executed with `Source/Android/gradlew <t
 
 Most dependencies for the Android project are supplied by Gradle automatically. However, Android platform libraries (and a few Google-supplied supplementary libraries) must be downloaded through the Android package manager.
 
-1. Launch the Android SDK Manager from the commandline by executing `<sdk-path>/tools/android`, or by clicking on its icon in Android Studio's main toolbar:
+1. Launch the Android SDK Manager by clicking on its icon in Android Studio's main toolbar:
 ![Android Studio Package Icon][package-icon]
-2. At the bottom of the window, click "Deselect All", and then "Updates".
-3. Install or update the following packages:
-
-* SDK Platform, under "Android 5.0.1 (API 21)". This will allow compiling apps that target Lollipop.
-* Android Support Repository
-* Android Support Library
-* Google Repository
+2. Install or update the SDK Platform. Choose the API level selected as [compileSdkVersion](Source/Android/app/build.gradle#L5).
+3. Install or update the SDK Tools. CMake, LLDB and NDK. If you don't use android-studio, please check out https://github.com/Commit451/android-cmake-installer.
 
 In the future, if the project targets a newer version of Android, or use newer versions of the tools/build-tools packages, it will be necessary to use this tool to download updates.
 
 [components]: http://i.imgur.com/Oo1Fs93.png
 [package-icon]: http://i.imgur.com/NUpkAH8.png
 [gradle]: http://i.imgur.com/dXIH6o3.png
-[shortcut]: http://i.imgur.com/eCWP4Yy.png
+[shortcut]: http://i.imgur.com/eCWP4Yy.png

CMake/CCache.cmake

@@ -0,0 +1,11 @@
+find_program(CCACHE_BIN ccache)
+if(CCACHE_BIN)
+    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_BIN})
+    set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ${CCACHE_BIN})
+
+    # ccache uses -I when compiling without preprocessor, which makes clang complain.
+    if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
+        set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Qunused-arguments -fcolor-diagnostics")
+        set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Qunused-arguments -fcolor-diagnostics")
+    endif()
+endif()

CMake/CheckAndAddFlag.cmake

@@ -0,0 +1,49 @@
+include(CheckCCompilerFlag)
+include(CheckCXXCompilerFlag)
+
+# check_add_add_flag(<variable> <flag> [DEBUG_ONLY | RELEASE_ONLY])
+#
+# Add a C or C++ compilation flag to the current scope
+#
+# Can optionally add the flag to Debug or Release configurations only, use this when
+# targeting multi-configuration generators like Visual Studio or Xcode.
+# Release configurations means NOT Debug, so it will work for RelWithDebInfo or MinSizeRel too.
+#
+# If the flag is added successfully, the variables FLAG_C_<variable> and FLAG_CXX_<variable>
+# may be set to ON.
+#
+# Examples:
+#   check_and_add_flag(FOO -foo)
+#   check_and_add_flag(ONLYDEBUG -onlydebug DEBUG_ONLY)
+#   check_and_add_flag(OPTMAX -O9001 RELEASE_ONLY)
+
+function(check_and_add_flag var flag)
+  set(genexp_config_test "1")
+  if(ARGV2 STREQUAL "DEBUG_ONLY")
+    set(genexp_config_test "$<CONFIG:Debug>")
+  elseif(ARGV2 STREQUAL "RELEASE_ONLY")
+    set(genexp_config_test "$<NOT:$<CONFIG:Debug>>")
+  elseif(ARGV2)
+    message(FATAL_ERROR "check_and_add_flag called with incorrect arguments: ${ARGN}")
+  endif()
+
+  set(is_c "$<COMPILE_LANGUAGE:C>")
+  set(is_cxx "$<COMPILE_LANGUAGE:CXX>")
+
+  # The Visual Studio generators don't support COMPILE_LANGUAGE
+  # So we fail all the C flags and only actually test CXX ones
+  if(CMAKE_GENERATOR MATCHES "Visual Studio")
+    set(is_c "0")
+    set(is_cxx "1")
+  endif()
+
+  check_c_compiler_flag(${flag} FLAG_C_${var})
+  if(FLAG_C_${var})
+    add_compile_options("$<$<AND:${is_c},${genexp_config_test}>:${flag}>")
+  endif()
+
+  check_cxx_compiler_flag(${flag} FLAG_CXX_${var})
+  if(FLAG_CXX_${var})
+    add_compile_options("$<$<AND:${is_cxx},${genexp_config_test}>:${flag}>")
+  endif()
+endfunction()

CMake/CheckLib.cmake

@@ -0,0 +1,58 @@
+find_package(PkgConfig)
+
+macro(_internal_message msg)
+	if(NOT ${_is_quiet})
+		message(STATUS "${msg}")
+	endif()
+endmacro()
+
+macro(check_lib var pc lib)
+	set(_is_required 0)
+	set(_is_quiet 0)
+	set(_arg_list ${ARGN})
+	foreach(_arg ${ARGN})
+		if(_arg STREQUAL "REQUIRED")
+			list(REMOVE_ITEM _arg_list "REQUIRED")
+			set(_is_required 1)
+		endif()
+		if(_arg STREQUAL "QUIET")
+			list(REMOVE_ITEM _arg_list "QUIET")
+			set(_is_quiet 1)
+		endif()
+	endforeach()
+
+	if(PKG_CONFIG_FOUND AND NOT ${var}_FOUND)
+		pkg_search_module(${var} QUIET ${pc})
+	endif()
+
+	if(${var}_FOUND)
+		if(${var}_INCLUDE_DIRS)
+			include_directories(${${var}_INCLUDE_DIRS})
+		endif()
+		# Make sure include directories for headers found using find_path below
+		# are re-added when reconfiguring
+		if(${var}_INCLUDE)
+			include_directories(${${var}_INCLUDE})
+		endif()
+		_internal_message("${lib} found")
+	else()
+		find_library(${var} ${lib})
+		if(_arg_list)
+			find_path(${var}_INCLUDE ${_arg_list})
+		else()
+			set(${var}_INCLUDE FALSE)
+		endif()
+		if(${var} AND ${var}_INCLUDE)
+			include_directories(${${var}_INCLUDE})
+			_internal_message("${lib} found")
+			set(${var}_FOUND 1 CACHE INTERNAL "")
+		else()
+			if(_is_required)
+				message(FATAL_ERROR "${lib} is required but not found")
+			else()
+				_internal_message("${lib} not found")
+			endif()
+		endif()
+	endif()
+endmacro()
+

CMake/DolphinCompileDefinitions.cmake

@@ -0,0 +1,34 @@
+# Add a C or C++ compile definitions to the current scope
+#
+# dolphin_compile_definitions(def [def ...] [DEBUG_ONLY | RELEASE_ONLY])
+#
+# Can optionally add the definitions to Debug or Release configurations only, use this so we can
+# target multi-configuration generators like Visual Studio or Xcode.
+# Release configurations means NOT Debug, so it will work for RelWithDebInfo or MinSizeRel too.
+# The definitions are added to the COMPILE_DEFINITIONS folder property.
+# Supports generator expressions, unlike add_definitions()
+#
+# Examples:
+#   dolphin_compile_definitions(FOO) -> -DFOO
+#   dolphin_compile_definitions(_DEBUG DEBUG_ONLY) -> -D_DEBUG
+#   dolphin_compile_definitions(NDEBUG RELEASE_ONLY) -> -DNDEBUG
+#   dolphin_compile_definitions($<$<COMPILE_LANGUAGE:C>:THISISONLYFORC>)
+
+function(dolphin_compile_definitions)
+  set(defs ${ARGN})
+
+  list(GET defs -1 last_def)
+  list(REMOVE_AT defs -1)
+
+  set(genexp_config_test "1")
+  if(last_def STREQUAL "DEBUG_ONLY")
+    set(genexp_config_test "$<CONFIG:Debug>")
+  elseif(last_def STREQUAL "RELEASE_ONLY")
+    set(genexp_config_test "$<NOT:$<CONFIG:Debug>>")
+  else()
+    list(APPEND defs ${last_def})
+  endif()
+
+  set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS
+    "$<${genexp_config_test}:${defs}>")
+endfunction()

CMake/DolphinPostprocessBundle.cmake

@@ -0,0 +1,46 @@
+# This module can be used in two different ways.
+#
+# When invoked as `cmake -P DolphinPostprocessBundle.cmake`, it fixes up an
+# application folder to be standalone. It bundles all required libraries from
+# the system and fixes up library IDs. Any additional shared libraries, like
+# plugins, that are found under Contents/MacOS/ will be made standalone as well.
+#
+# When called with `include(DolphinPostprocessBundle)`, it defines a helper
+# function `dolphin_postprocess_bundle` that sets up the command form of the
+# module as a post-build step.
+
+if(CMAKE_GENERATOR)
+	# Being called as include(DolphinPostprocessBundle), so define a helper function.
+	set(_DOLPHIN_POSTPROCESS_BUNDLE_MODULE_LOCATION "${CMAKE_CURRENT_LIST_FILE}")
+	function(dolphin_postprocess_bundle target)
+		add_custom_command(TARGET ${target} POST_BUILD
+			COMMAND ${CMAKE_COMMAND} -DDOLPHIN_BUNDLE_PATH="$<TARGET_FILE_DIR:${target}>/../.."
+				-P "${_DOLPHIN_POSTPROCESS_BUNDLE_MODULE_LOCATION}"
+		)
+	endfunction()
+	return()
+endif()
+
+get_filename_component(DOLPHIN_BUNDLE_PATH "${DOLPHIN_BUNDLE_PATH}" REALPATH)
+message(STATUS "Fixing up application bundle: ${DOLPHIN_BUNDLE_PATH}")
+
+# Make sure to fix up any additional shared libraries (like plugins) that are
+# needed.
+file(GLOB_RECURSE extra_libs "${DOLPHIN_BUNDLE_PATH}/Contents/MacOS/*.dylib")
+
+# BundleUtilities doesn't support DYLD_FALLBACK_LIBRARY_PATH behavior, which
+# makes it sometimes break on libraries that do weird things with @rpath. Specify
+# equivalent search directories until https://gitlab.kitware.com/cmake/cmake/issues/16625
+# is fixed and in our minimum CMake version.
+set(extra_dirs "/usr/local/lib" "/lib" "/usr/lib")
+
+# BundleUtilities is overly verbose, so disable most of its messages
+function(message)
+	if(NOT ARGV MATCHES "^STATUS;")
+		_message("${ARGV}")
+	endif()
+endfunction()
+
+include(BundleUtilities)
+set(BU_CHMOD_BUNDLE_ITEMS ON)
+fixup_bundle("${DOLPHIN_BUNDLE_PATH}" "${extra_libs}" "${extra_dirs}")

CMake/FindALSA.cmake

@@ -0,0 +1,59 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file Copyright.txt or https://cmake.org/licensing for details.
+
+#.rst:
+# FindALSA
+# --------
+#
+# Find alsa
+#
+# Find the alsa libraries (asound)
+#
+# ::
+#
+#   This module defines the following variables:
+#      ALSA_FOUND       - True if ALSA_INCLUDE_DIR & ALSA_LIBRARY are found
+#      ALSA_LIBRARIES   - Set when ALSA_LIBRARY is found
+#      ALSA_INCLUDE_DIRS - Set when ALSA_INCLUDE_DIR is found
+#
+#
+#
+# ::
+#
+#      ALSA_INCLUDE_DIR - where to find asoundlib.h, etc.
+#      ALSA_LIBRARY     - the asound library
+#      ALSA_VERSION_STRING - the version of alsa found (since CMake 2.8.8)
+
+find_path(ALSA_INCLUDE_DIR NAMES alsa/asoundlib.h
+          DOC "The ALSA (asound) include directory"
+)
+
+find_library(ALSA_LIBRARY NAMES asound
+          DOC "The ALSA (asound) library"
+)
+
+if(ALSA_INCLUDE_DIR AND EXISTS "${ALSA_INCLUDE_DIR}/alsa/version.h")
+  file(STRINGS "${ALSA_INCLUDE_DIR}/alsa/version.h" alsa_version_str REGEX "^#define[\t ]+SND_LIB_VERSION_STR[\t ]+\".*\"")
+
+  string(REGEX REPLACE "^.*SND_LIB_VERSION_STR[\t ]+\"([^\"]*)\".*$" "\\1" ALSA_VERSION_STRING "${alsa_version_str}")
+  unset(alsa_version_str)
+endif()
+
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(ALSA
+                                  REQUIRED_VARS ALSA_LIBRARY ALSA_INCLUDE_DIR
+                                  VERSION_VAR ALSA_VERSION_STRING)
+
+if(ALSA_FOUND)
+  set( ALSA_LIBRARIES ${ALSA_LIBRARY} )
+  set( ALSA_INCLUDE_DIRS ${ALSA_INCLUDE_DIR} )
+  if(NOT TARGET ALSA::ALSA)
+    add_library(ALSA::ALSA UNKNOWN IMPORTED)
+    set_target_properties(ALSA::ALSA PROPERTIES
+      IMPORTED_LOCATION ${ALSA_LIBRARY}
+      INTERFACE_INCLUDE_DIRECTORIES ${ALSA_INCLUDE_DIR}
+    )
+  endif()
+endif()
+
+mark_as_advanced(ALSA_INCLUDE_DIR ALSA_LIBRARY)