settings.gradle

//
// Copyright (c) ZeroC, Inc. All rights reserved.
//

// Map of dir->subdir for each of the demos.
def demos = [
    'Ice' : ['async', 'asyncInvocation', 'bidir', 'callback', 'hello',
             'interceptor', 'interrupt', 'invoke', 'latency', 'minimal',
             'multicast', 'nested', 'plugin', 'properties', 'serialize',
             'session', 'swing', 'throughput', 'optional', 'context'],
    'IceDiscovery' : ['hello', 'replication'],
    'IceBox' : ['hello'],
    'Glacier2' : ['callback'],
    'IceStorm' : ['clock'],
    'IceGrid' : ['icebox', 'simple'],
    'Manual' : ['printer', 'simpleFilesystem']
]

demos.each {
    def dir = it.key
    def subdirs = it.value

    subdirs.each {
        // abc_def -> AbcDef
        def name = it.split('_').collect { it.capitalize() }.join()

        // A project in directory xyz is demoXyzAbcDef
        def projectName = ":demo${dir.capitalize()}${name}"
        include projectName

        // The directory is <dir>/<name>.
        project("${projectName}").projectDir = new File("${dir}/${it}")
    }
}