-
Notifications
You must be signed in to change notification settings - Fork 34
/
Copy pathmodular_binomial_faster.pl
315 lines (236 loc) · 8.62 KB
/
modular_binomial_faster.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
#!/usr/bin/perl
# Translated by: Trizen
# Date: 27 April 2022
# https://github.com/trizen
# Fast algorithm for computing the binomial coefficient modulo some integer m.
# The implementation is based on Lucas' Theorem and its generalization given in the paper
# Andrew Granville "The Arithmetic Properties of Binomial Coefficients", In Proceedings of
# the Organic Mathematics Workshop, Simon Fraser University, December 12-14, 1995.
# Translation of binomod.gp v1.5 by Max Alekseyev, with some minor optimizations.
# See also:
# https://home.gwu.edu/~maxal/gpscripts/
use 5.020;
use strict;
use warnings;
use ntheory qw(:all);
use Math::AnyNum qw(ilog);
use experimental qw(signatures);
sub factorial_without_prime ($n, $p, $pk, $from, $count, $res) {
return 1 if ($n <= 1);
if ($p > $n) {
return factorialmod($n, $pk);
}
if ($$from == $n) {
return $$res;
}
if ($$from > $n) {
$$from = 0;
$$count = 0;
$$res = 1;
}
my $r = $$res;
my $t = $$count;
foreach my $v ($$from + 1 .. $n) {
if (++$t == $p) {
$t = 0;
}
else {
$r = mulmod($r, $v, $pk);
}
}
$$res = $r;
$$count = $t;
$$from = $n;
return $r;
}
sub lucas_theorem ($n, $k, $p) { # p is prime
my $r = 1;
while ($k) {
my $np = modint($n, $p);
my $kp = modint($k, $p);
if ($kp > $np) { return 0 }
my $rp = subint($np, $kp);
my $x = factorialmod($np, $p);
my $y = factorialmod($kp, $p);
my $z = factorialmod($rp, $p);
$y = mulmod($y, $z, $p);
$x = divmod($x, $y, $p);
$r = mulmod($r, $x, $p);
$n = divint($n, $p);
$k = divint($k, $p);
}
return $r;
}
sub modular_binomial ($n, $k, $m) {
if ($m == 0) {
return undef;
}
if ($m == 1) {
return 0;
}
if ($k < 0) {
$k = subint($n, $k);
}
if ($k < 0) {
return 0;
}
if ($n < 0) {
return modint(mulint(powint(-1, $k), __SUB__->(subint($k, $n) - 1, $k, $m)), $m);
}
if ($k > $n) {
return 0;
}
if ($k == 0 or $k == $n) {
return modint(1, $m);
}
if ($k == 1 or $k == subint($n, 1)) {
return modint($n, $m);
}
my @F;
foreach my $pp (factor_exp(absint($m))) {
my ($p, $q) = @$pp;
if ($q == 1) {
push @F, [lucas_theorem($n, $k, $p), $p];
next;
}
#my $d = logint($n, $p) + 1; # incorrect for large p
my $d = ilog($n, $p) + 1;
my (@np, @kp);
do {
my $pi = 1;
foreach my $i (0 .. $d) {
push @np, modint(divint($n, $pi), $p);
push @kp, modint(divint($k, $pi), $p);
$pi = mulint($pi, $p);
}
};
my @e;
foreach my $i (0 .. $d) {
$e[$i] = ($np[$i] < ($kp[$i] + (($i > 0) ? $e[$i - 1] : 0))) ? 1 : 0;
}
for (my $i = $d - 1 ; $i >= 0 ; --$i) {
$e[$i] += $e[$i + 1];
}
if ($e[0] >= $q) {
push @F, [0, powint($p, $q)];
next;
}
my $rq = $q - $e[0];
my $pq = powint($p, $q);
my $prq = powint($p, $rq);
my (@N, @K, @R);
do {
my $pi = 1;
my $r = subint($n, $k);
foreach my $i (0 .. $d) {
push @N, modint(divint($n, $pi), $prq);
push @K, modint(divint($k, $pi), $prq);
push @R, modint(divint($r, $pi), $prq);
$pi = mulint($pi, $p);
}
};
my @NKR = (
sort { $a->[3] <=> $b->[3] }
map { [$N[$_], $K[$_], $R[$_], $N[$_] + $K[$_] + $R[$_]] } 0 .. $#N
);
@N = map { $_->[0] } @NKR;
@K = map { $_->[1] } @NKR;
@R = map { $_->[2] } @NKR;
my @acc = (1);
my $nfac = 1;
if ($prq < ~0 and $p < $n) {
my $count = 0;
foreach my $k (1 .. vecmin(vecmax(@N, @K, @R), 1e4)) {
if (++$count == $p) {
$count = 0;
}
else {
$nfac = mulmod($nfac, $k, $prq);
}
push @acc, $nfac;
}
}
my $v = powmod($p, $e[0], $pq);
do {
my $from = 0;
my $count = 0;
my $res = 1;
foreach my $j (0 .. $d) {
my @pairs;
my ($x, $y, $z);
($x = $acc[$N[$j]]) // push(@pairs, [\$x, $N[$j]]);
($y = $acc[$K[$j]]) // push(@pairs, [\$y, $K[$j]]);
($z = $acc[$R[$j]]) // push(@pairs, [\$z, $R[$j]]);
foreach my $pair (sort { $a->[1] <=> $b->[1] } @pairs) {
${$pair->[0]} = factorial_without_prime($pair->[1], $p, $prq, \$from, \$count, \$res);
}
$v = mulmod($v, divmod($x, mulmod($y, $z, $pq), $pq), $pq);
}
};
if (($p > 2 or $rq < 3) and $q <= scalar(@e)) {
$v = mulmod($v, powint(-1, $e[$rq - 1]), $pq);
}
push @F, [$v, $pq];
}
modint(chinese(@F), $m);
}
#
## Run some tests
#
use Test::More tests => 44;
is(modular_binomial(10, 2, 43), 2);
is(modular_binomial(10, 8, 43), 2);
is(modular_binomial(10, 2, 24), 21);
is(modular_binomial(10, 8, 24), 21);
is(modular_binomial(100, 42, -127), binomial(100, 42) % -127);
is(modular_binomial(12, 5, 100000), 792);
is(modular_binomial(16, 4, 100000), 1820);
is(modular_binomial(100, 50, 139), 71);
is(modular_binomial(1000, 10, 1243), 848);
is(modular_binomial(124, 42, 1234567), 395154);
is(modular_binomial(1e9, 1e4, 1234567), 833120);
is(modular_binomial(1e10, 1e5, 1234567), 589372);
is(modular_binomial(1e10, 1e5, 4233330243), 3403056024);
is(modular_binomial(-1e10, 1e5, 4233330243), 2865877173);
is(modular_binomial(1e10, 1e4, factorial(13)), 1845043200);
is(modular_binomial(1e10, 1e5, factorial(13)), 1556755200);
is(modular_binomial(1e10, 1e6, factorial(13)), 5748019200);
is(modular_binomial(-1e10, 1e4, factorial(13)), 4151347200);
is(modular_binomial(-1e10, 1e5, factorial(13)), 1037836800);
is(modular_binomial(-1e10, 1e6, factorial(13)), 2075673600);
is(modular_binomial(3, 1, 9), binomial(3, 1) % 9);
is(modular_binomial(4, 1, 16), binomial(4, 1) % 16);
is(modular_binomial(1e9, 1e5, 43 * 97 * 503), 585492);
is(modular_binomial(1e9, 1e6, 5041689707), 15262431);
is(modular_binomial(1e7, 1e5, 43**2 * 97**3 * 13**4), 1778017500428);
is(modular_binomial(1e7, 1e5, 42**2 * 97**3 * 13**4), 10015143223176);
is(modular_binomial(1e9, 1e5, 12345678910), 4517333900);
is(modular_binomial(1e9, 1e6, 13**2 * 5**6), 2598375);
is(modular_binomial(1e10, 1e5, 1234567), 589372);
is(modular_binomial(1e5, 1e3, 43), binomial(1e5, 1e3) % 43);
is(modular_binomial(1e5, 1e3, 43 * 97), binomial(1e5, 1e3) % (43 * 97));
is(modular_binomial(1e5, 1e3, 43 * 97 * 43), binomial(1e5, 1e3) % (43 * 97 * 43));
is(modular_binomial(1e5, 1e3, 43 * 97 * (5**5)), binomial(1e5, 1e3) % (43 * 97 * (5**5)));
is(modular_binomial(1e5, 1e3, next_prime(1e4)**2), binomial(1e5, 1e3) % next_prime(1e4)**2);
is(modular_binomial(1e5, 1e3, next_prime(1e4)), binomial(1e5, 1e3) % next_prime(1e4));
is(modular_binomial(1e6, 1e3, next_prime(1e5)), binomial(1e6, 1e3) % next_prime(1e5));
is(modular_binomial(1e6, 1e3, next_prime(1e7)), binomial(1e6, 1e3) % next_prime(1e7));
is(modular_binomial(1234567, 1e3, factorial(20)), binomial(1234567, 1e3) % factorial(20));
is(modular_binomial(1234567, 1e4, factorial(20)), binomial(1234567, 1e4) % factorial(20));
is(modular_binomial(1e6, 1e3, powint(2, 128) + 1), binomial(1e6, 1e3) % (powint(2, 128) + 1));
is(modular_binomial(1e6, 1e3, powint(2, 128) - 1), binomial(1e6, 1e3) % (powint(2, 128) - 1));
is(modular_binomial(1e6, 1e4, (powint(2, 128) + 1)**2), binomial(1e6, 1e4) % ((powint(2, 128) + 1)**2));
is(modular_binomial(1e6, 1e4, (powint(2, 128) - 1)**2), binomial(1e6, 1e4) % ((powint(2, 128) - 1)**2));
is(modular_binomial(-10, -9, -10), binomial(-10, -9) % -10);
say("binomial(10^10, 10^5) mod 13! = ", modular_binomial(1e10, 1e5, factorial(13)));
__END__
my $upto = 10;
foreach my $n (-$upto .. $upto) {
foreach my $k (-$upto .. $upto) {
foreach my $m (-$upto .. $upto) {
next if ($m == 0);
say "Testing: binomial($n, $k, $m)";
is(modular_binomial($n, $k, $m), binomial($n, $k) % $m);
}
}
}