build.gradle

group = artifact_group
version = "${artifact_version}.${build_number}"

apply plugin: 'groovy'
apply plugin: 'maven'

repositories {
	mavenCentral()
}

dependencies {
    compile gradleApi()
    compile localGroovy()
    testCompile gradleTestKit()
}

task wrapper(type: Wrapper) {
    gradleVersion = "2.10"
}

test {
    // Always run the tests
    outputs.upToDateWhen { false }

    // Turn on some console logging
    testLogging {
        events "passed", "skipped", "failed"
        exceptionFormat "full"
        stackTraceFilters "entryPoint"
    }
}

// Write the plugin's classpath to a file to share with the tests
task createClasspathManifest {
    def outputDir = file("$buildDir/$name")

    inputs.files sourceSets.main.runtimeClasspath
    outputs.dir outputDir

    doLast {
        outputDir.mkdirs()
        file("$outputDir/plugin-classpath.txt").text = sourceSets.main.runtimeClasspath.join("\n")
    }
}

// Add the classpath file to the test runtime classpath
dependencies {
    testRuntime files(createClasspathManifest)
}

sourceCompatibility = 1.7
targetCompatibility = 1.7