publish-maven.gradle

/*
 * Copyright 2002-2025 the original author or authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     https://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

// see https://docs.gradle.org/current/userguide/publishing_maven.html
apply plugin: 'maven-publish'

publishing {
	repositories {
		maven {
			url = project.properties.getOrDefault('publicationRepository', "${System.getenv('HOME')}/.m2/repository")
		}
	}
	publications {
		mavenJava(MavenPublication) {
			suppressAllPomMetadataWarnings()
			from components.java
			pom {
				afterEvaluate {
					if (project.description == null || project.description.isEmpty()) {
						throw new InvalidUserDataException("A project description is required for publishing to maven central")
					}
					name = project.description
					description = project.description
				}
				url = "https://spring.io/projects/spring-cloud-open-service-broker"
				organization {
					name = "VMware, Inc."
					url = "https://spring.io"
				}
				licenses {
					license {
						name = "The Apache Software License, Version 2.0"
						url = "https://www.apache.org/licenses/LICENSE-2.0.txt"
						distribution = "repo"
					}
				}
				scm {
					url = "https://github.com/spring-cloud/spring-cloud-open-service-broker"
					connection = "scm:git:git://github.com/spring-cloud/spring-cloud-open-service-broker"
					developerConnection = "scm:git:git://github.com/spring-cloud/spring-cloud-open-service-broker"
				}
				issueManagement {
					system = "GitHub"
					url = "https://github.com/spring-cloud/spring-cloud-open-service-broker/issues"
				}
				developers {
					developer {
						id = "royclarkson"
						name = "Roy Clarkson"
						email = "roy.clarkson@broadcom.com"
					}
				}
			}

			// Published pom will use fully-qualified dependency versions and no BOMs
			versionMapping {
				usage('java-api') {
					fromResolutionOf('runtimeClasspath')
				}
				usage('java-runtime') {
					fromResolutionResult()
				}
			}
			pom.withXml {
				def pomNode = asNode()
				def dependencyManagementNode = pomNode.get('dependencyManagement')
				if (dependencyManagementNode) {
					pomNode.remove(dependencyManagementNode)
				}
			}
		}
	}
}