-
Notifications
You must be signed in to change notification settings - Fork 13
/
Copy path_zewdYUIRuntime.m
370 lines (370 loc) · 14 KB
/
_zewdYUIRuntime.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
%zewdYUIRuntime ; YUI Tags: Runtime logic
;
; Product: Enterprise Web Developer (Build 910)
; Build Date: Wed, 25 Apr 2012 17:59:26
;
; ----------------------------------------------------------------------------
; | Enterprise Web Developer for GT.M and m_apache |
; | Copyright (c) 2004-12 M/Gateway Developments Ltd, |
; | Reigate, Surrey UK. |
; | All rights reserved. |
; | |
; | http://www.mgateway.com |
; | Email: [email protected] |
; | |
; | This program is free software: you can redistribute it and/or modify |
; | it under the terms of the GNU Affero General Public License as |
; | published by the Free Software Foundation, either version 3 of the |
; | License, or (at your option) any later version. |
; | |
; | This program is distributed in the hope that it will be useful, |
; | but WITHOUT ANY WARRANTY; without even the implied warranty of |
; | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
; | GNU Affero General Public License for more details. |
; | |
; | You should have received a copy of the GNU Affero General Public License |
; | along with this program. If not, see <http://www.gnu.org/licenses/>. |
; ----------------------------------------------------------------------------
;
QUIT
;
;
menuBarRedirect(sessid)
;
n allowed,nvp,page,widgetId
;
d mergeArrayFromSession^%zewdAPI(.allowed,"YUIMenuBarAllowedPages",sessid)
s widgetId=$$getRequestValue^%zewdAPI("widgetId",sessid)
s page=$$getRequestValue^%zewdAPI("fragment",sessid)
s nvp=$$getRequestValue^%zewdAPI("nvp",sessid)
i nvp'="" d setSessionValue^%zewdAPI("yui_TreeView.nvp",nvp,sessid)
i $d(allowed(widgetId,page)) d setRedirect^%zewdAPI(page,sessid) QUIT ""
QUIT "Unauthorised page request"
;
getDTPageParams(sessid)
;
n count,data,direction,n,newDir,newSort,prevDir,prevSort,sessionName
;
s sessionName=$$getRequestValue^%zewdAPI("data",sessid)
i sessionName="" QUIT ""
i '$$sessionNameExists^%zewdAPI(sessionName,sessid) QUIT ""
d setSessionValue^%zewdAPI("YUIDataTableData",sessionName,sessid)
s count=$$getSessionValue^%zewdAPI("YUIDataTableTotalRows",sessid)
i count="" d
. s count=0,n=""
. d mergeArrayFromSession^%zewdAPI(.data,sessionName,sessid)
. f s n=$o(data(n)) q:n="" s count=count+1
. k data
. d setSessionValue^%zewdAPI("YUIDataTableTotalRows",count,sessid)
s prevDir=$$getSessionValue^%zewdAPI("dir",sessid)
d copyRequestValueToSession^%zewdAPI("dir",sessid)
s newDir=$$getSessionValue^%zewdAPI("dir",sessid)
d copyRequestValueToSession^%zewdAPI("results",sessid)
d copyRequestValueToSession^%zewdAPI("startIndex",sessid)
s prevSort=$$getSessionValue^%zewdAPI("sort",sessid)
d copyRequestValueToSession^%zewdAPI("sort",sessid)
s newSort=$$getSessionValue^%zewdAPI("sort",sessid)
i prevDir'=newDir,prevSort'="" s prevSort=""
s direction=1 i newDir="desc" s direction=-1
i newSort'=prevSort d
. n data2,sort,value
. d mergeArrayFromSession^%zewdAPI(.data,sessionName,sessid)
. s n=""
. f s n=$o(data(n)) q:n="" d
. . s value=$g(data(n,newSort))
. . s sort(value,n)=""
. s value="",no=0
. f s value=$o(sort(value),direction) q:value="" d
. . s n=""
. . f s n=$o(sort(value,n)) q:n="" d
. . . s no=no+1
. . . m data2(no)=data(n)
. d deleteFromSession^%zewdAPI(sessionName,sessid)
. d mergeArrayToSession^%zewdAPI(.data2,sessionName,sessid)
QUIT ""
;
DTPagedData(sessid)
;
n count,data,dir,result,row,sArray,sessionName,sort,startIndex
;
s startIndex=$$getSessionValue^%zewdAPI("startIndex",sessid)
s result=$$getSessionValue^%zewdAPI("results",sessid)
s sort=$$getSessionValue^%zewdAPI("sort",sessid)
s dir=$$getSessionValue^%zewdAPI("dir",sessid)
s sessionName=$$getSessionValue^%zewdAPI("YUIDataTableData",sessid)
d mergeArrayFromSession^%zewdAPI(.data,sessionName,sessid)
s count=$$getSessionValue^%zewdAPI("YUIDataTableTotalRows",sessid)
;
f row=(startIndex+1):1:(startIndex+result) d
. m sArray("zobj1","records",row,"zobj1")=data(row)
s sArray("zobj1","recordsReturned")=result
s sArray("zobj1","totalRecords")=count
s sArray("zobj1","startIndex")=startIndex
s sArray("zobj1","sort")=sort
s sArray("zobj1","dir")=dir
s sArray("zobj1","pageSize")=result
d walkObjectArray^%zewdCompiler19("sArray")
w $c(13,10)
w !
QUIT
;
createDataTableStore(array,sessionName,sessid)
;
n jrow,name,row,sArray,value
;
s row=""
f s row=$o(array(row)) q:row="" d
. s name=""
. f s name=$o(array(row,name)) q:name="" d
. . s value=array(row,name)
. . s jrow=$j(row,6)
. . s jrow=$tr(jrow," ","0")
. . s sArray(1,"zobj"_jrow,name)=value
d deleteFromSession^%zewdAPI(sessionName,sessid)
d mergeArrayToSession^%zewdAPI(.sArray,sessionName,sessid)
QUIT
;
writeTreeOptions(sessionName,onclick,widgetId,widgetObj,targetId,sessid)
;
n allowed,allowedList,array,node,ref
;
d mergeArrayFromSession^%zewdAPI(.array,sessionName,sessid)
d mergeArrayFromSession^%zewdAPI(.allowed,"YUIMenuBarAllowedPages",sessid)
k allowed(widgetId)
s node=widgetObj_".getRoot()"
s ref="array("
w "EWD.yui.treeViewOptions['"_widgetId_"'] = {} ;"
d getSubTreeOptions(.array,ref,node,widgetId,0,targetId,.allowedList,sessid)
m allowed(widgetId)=allowedList
d deleteFromSession^%zewdAPI("YUIMenuBarAllowedPages",sessid)
d mergeArrayToSession^%zewdAPI(.allowed,"YUIMenuBarAllowedPages",sessid)
QUIT
;
getSubTreeOptions(array,refn,parentNode,widgetId,nodeNo,targetId,allowed,sessid)
;
n comma,expanded,id1,nvp,page,refb,refExpanded,refId,refNVP
n refPage,refTarget,refText,refTitle,refTranslate,subref
n subrefx,target,text,title,translate,x,xtext,zzno
;
s comma=""
i $e(refn,$l(refn))'="(" s comma=","
s refb=refn_comma_"zzno)"
s refText=refn_comma_"zzno,""text"")"
s refId=refn_comma_"zzno,""id"")"
s refPage=refn_comma_"zzno,""page"")"
s refTarget=refn_comma_"zzno,""target"")"
s refNVP=refn_comma_"zzno,""nvp"")"
s refExpanded=refn_comma_"zzno,""expanded"")"
s refTitle=refn_comma_"zzno,""title"")"
s refTranslate=refn_comma_"zzno,""translate"")"
s zzno=""
s x="s zzno=$o("_refb_")"
f x x q:zzno="" d
. s text=$g(@refText)
. s translate=$g(@refTranslate)
. s xyext=""
. i translate'=0 s xtext=$$systemMessage^%zewdAPI(text,"yui",sessid)
. i xtext'="",translate'=0 s text=xtext
. s id1=$g(@refId)
. s page=$g(@refPage)
. s target=$g(@refTarget)
. i target="" s target=targetId
. s nvp=$g(@refNVP)
. s expanded=$g(@refExpanded)
. i expanded="" s expanded="false"
. s title=$g(@refTitle)
. i title'="" s title=",title:"""_title_""""
. s nodeNo=nodeNo+1
. w "var treeNode"_nodeNo_" = new YAHOO.widget.TextNode({label:"""_text_""",expanded:"_expanded_title_"}, "_parentNode_");"
. i page'="" d
. . w "treeNode"_nodeNo_".href=""javascript:EWD.yui.treeViewSelector('"_widgetId_"',"_nodeNo_")"";"
. . i target'="" s $p(page,"~",2)=target
. . i nvp'="" s $p(page,"~",3)=nvp
. . s $p(page,"~",4)=expanded
. . w "EWD.yui.treeViewOptions['"_widgetId_"']["_nodeNo_"]='"_page_"' ;"
. . s allowed($p(page,"~",1))=""
. s subref=refn_comma_zzno_",""submenu"""
. s subrefx=subref_")"
. i $d(@subrefx) d
. . n node,nox
. . s node="treeNode"_nodeNo
. . s nox=zzno
. . d getSubTreeOptions(.array,subref,node,widgetId,.nodeNo,targetId,.allowed,sessid)
. . s zzno=nox
QUIT
;
writeMenuOptions(sessionName,onclick,widgetId,sessid)
;
n allowed,allowedList,array,idx,ref
;
d mergeArrayFromSession^%zewdAPI(.array,sessionName,sessid)
d mergeArrayFromSession^%zewdAPI(.allowed,"YUIMenuBarAllowedPages",sessid)
k allowed(widgetId)
w "<div class='bd'>"
w "<ul class='first-of-type'>"
s ref="array("
s idx=""
d getSubMenuOptions(.array,ref,idx,onclick,widgetId,.allowedList,sessid)
w "</ul>"
w "</div>"
m allowed(widgetId)=allowedList
d deleteFromSession^%zewdAPI("YUIMenuBarAllowedPages",sessid)
d mergeArrayToSession^%zewdAPI(.allowed,"YUIMenuBarAllowedPages",sessid)
QUIT
;
getSubMenuOptions(array,refn,id,onclick,widgetId,allowed,sessid)
;
n bar,comma,fot,href,id1,page,refb,refId,refPage,refTarget,refText
n refTranslate,subref,subrefx,target,text,translate,x,xtext,zzno
;
s comma="",bar="bar"
i $e(refn,$l(refn))'="(" s comma=",",bar=""
s refb=refn_comma_"zzno)"
s refText=refn_comma_"zzno,""text"")"
s refId=refn_comma_"zzno,""id"")"
s refPage=refn_comma_"zzno,""page"")"
s refTarget=refn_comma_"zzno,""target"")"
s refTranslate=refn_comma_"zzno,""translate"")"
s zzno=""
s x="s zzno=$o("_refb_")"
f x x q:zzno="" d
. s text=$g(@refText)
. s translate=$g(@refTranslate)
. s xtext=""
. i translate'=0 s xtext=$$systemMessage^%zewdAPI(text,"yui",sessid)
. i xtext'=0,xtext'="" s text=xtext
. s id1=$g(@refId)
. s page=$g(@refPage)
. s target=$g(@refTarget)
. s fot=""
. w "<li class='yuimenu"_bar_"item"_fot_"'>"
. s href="'#'"
. i onclick'="",id1'="" s href="javascript:"_onclick_"('"_id1_"')"
. i page'="" d
. . n tgt
. . s tgt="" i target'="" s target=",'"_target_"'"
. . s href="""javascript:EWD.yui.menuBarSelector('"_widgetId_"','"_page_"'"_target_")"""
. . s allowed(page)=""
. s subref=refn_comma_zzno_",""submenu"""
. s subrefx=subref_")"
. s href="href="_href
. ;i $d(@subrefx) s href=""
. w "<a class='yuimenu"_bar_"itemlabel' "_href_">"_text_"</a>"
. i $d(@subrefx) d
. . n idx,nox
. . w "<div id='MenuBar"_id_zzno_"' class='yuimenu' style='z-index:20'>"
. . w "<div class='bd'>"
. . ;w "<ul class='first-of-type'>"
. . w "<ul>"
. . s nox=zzno
. . s idx=id_zzno_"-"
. . d getSubMenuOptions(.array,subref,idx,onclick,widgetId,.allowed,sessid)
. . w "</ul>"
. . w "</div>"
. . w "</div>"
. . s zzno=nox
. w "</li>"
QUIT
;
writeDataTableFunctions(sessionName,sessid)
;
n colDef,func,key,no
;
d mergeArrayFromSession^%zewdAPI(.colDef,sessionName,sessid)
f no=1:1 q:'$d(colDef(no)) d
. i $d(colDef(no,"onclick")) d
. . s key=$g(colDef(no,"key"))
. . s func=$g(colDef(no,"onclick"))
. . w "buttonFuncs["""_key_"""] = function(rowNo,oRecord) {"_func_"(rowNo,oRecord);};"_$c(13,10)
QUIT
;
createDropdownOptionsJSON(menuArray)
;
n comma,json,no
;
s no="",json="[",comma=""
f s no=$o(menuArray(no)) q:no="" d
. s json=json_comma_"{"
. s json=json_"label:'"_$g(menuArray(no,"label"))_"'"
. s json=json_",value:'"_$g(menuArray(no,"value"))_"'"
. s json=json_"}"
. s comma=","
s json=json_"]"
QUIT json
;
writeDataTableColumns(uniqueName,nodeNo,sessionName,addEditor,editorControlKey,sessid)
;
n colDef,columnSet,comma,comma2,comma3,fields,name,namex,no,value
;
d mergeArrayFromSession^%zewdAPI(.colDef,sessionName,sessid)
s no="",columnSet="",fields="",comma2="",comma3="",addEditor=0
f no=1:1 q:'$d(colDef(no)) d
. w "var yuiDataTableCol"_uniqueName_no_"=new YAHOO.widget.Column({"
. s name="",comma=""
. f s name=$o(colDef(no,name)) q:name="" d
. . s value=colDef(no,name)
. . d
. . . n key
. . . s namex=name
. . . i name="type" d q
. . . . s namex="formatter"
. . . . i value="button" s value="YAHOO.widget.DataTable.formatButton" q
. . . . i value="date" s value="YAHOO.widget.DataTable.formatDate" q
. . . . i value="number" s value="YAHOO.widget.DataTable.formatNumber" q
. . . . i value="currency" s value="YAHOO.widget.DataTable.formatCurrency" q
. . . i name="resizeable"!(name="sortable")!(name="hidden") q
. . . i value?1N.N q
. . . i name="header" d
. . . . s namex="label"
. . . . s value=$$systemMessage^%zewdAPI(value,"yui",sessid)
. . . i $$zcvt^%zewdAPI(name)="editas" d q
. . . . s namex="editor"
. . . . s value="new YAHOO.widget.TextboxCellEditor({disableBtns:true})"
. . . . s addEditor=1
. . . i $$zcvt^%zewdAPI(name)="dynamiceditorkey" d q
. . . . s key=$g(colDef(no,"key"))
. . . . i key'="" s editorControlKey(key)=value
. . . . s addEditor=1
. . . . s namex="editor"
. . . . s value="new YAHOO.widget.BaseCellEditor()"
. . . i name="editor" s addEditor=1 q
. . . i name="formatter" q
. . . s value=""""_value_""""
. . w comma_namex_":"_value
. . i name="key" s fields=fields_comma3_value,comma3=","
. . s comma=","
. w "});"_$c(13,10)
. s columnSet=columnSet_comma2_"yuiDataTableCol"_uniqueName_no
. s comma2=","
w "var yuiColumnDefs"_uniqueName_nodeNo_"=new YAHOO.widget.ColumnSet(["_columnSet_"]);"_$c(13,10)
w "yuiDataSource"_uniqueName_nodeNo_".responseSchema={fields:["_fields_"]};"_$c(13,10)
QUIT
;
writeEditorHandlers(tableObj,addEditor,editorControlKey)
;
n controlKey,key
;
i addEditor d
. w tableObj_".subscribe('cellClickEvent',"_tableObj_".onEventShowCellEditor);"_$c(13,10)
. w tableObj_".subscribe('cellMouseoverEvent',"_tableObj_".onEventHighlightCell);"_$c(13,10)
. w tableObj_".subscribe('cellMouseoutEvent',"_tableObj_".onEventUnhighlightCell);"_$c(13,10)
;
s key=""
f s key=$o(editorControlKey(key)) q:key="" d
. s controlKey=editorControlKey(key)
. w tableObj_".subscribe(""cellClickEvent"", function(oArgs){"_$c(13,10)
. w " var target = oArgs.target;"_$c(13,10)
. w " var key = this.getColumn(target).getKey();"_$c(13,10)
. w " if (key == '"_key_"') {"_$c(13,10)
. w " var editorType = this.getRecord(target).getData('"_controlKey_"');"_$c(13,10)
. w " var params = EWD.utils.getPiece(editorType,'|',2);"_$c(13,10)
. w " var editorType = EWD.utils.getPiece(editorType,'|',1);"_$c(13,10)
. w " var editorRef = 'new YAHOO.widget.';"_$c(13,10)
. w " if (editorType == 'text') editorRef = editorRef + 'TextboxCellEditor(' + params + ')';"_$c(13,10)
. w " if (editorType == 'menu') editorRef = editorRef + 'DropdownCellEditor({disableBtns:true,dropdownOptions:' + params + '})';"_$c(13,10)
. w " eval('this.getColumn(target).editor=' + editorRef);"_$c(13,10)
. w " this.showCellEditor(target);"_$c(13,10)
. w " }"_$c(13,10)
. w "});"_$c(13,10)
QUIT
;