-
Notifications
You must be signed in to change notification settings - Fork 13
/
Copy path_zewdHTMLParser.m
1862 lines (1862 loc) · 60.2 KB
/
_zewdHTMLParser.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%zewdHTMLParser ; Enterprise Web Developer HTML to XHTML Converter
;
; Product: Enterprise Web Developer (Build 965)
; Build Date: Thu, 15 Aug 2013 17:14:16
;
; ----------------------------------------------------------------------------
; | Enterprise Web Developer for GT.M and m_apache |
; | Copyright (c) 2004-12 M/Gateway Developments Ltd, |
; | Reigate, Surrey UK. |
; | All rights reserved. |
; | |
; | http://www.mgateway.com |
; | Email: [email protected] |
; | |
; | This program is free software: you can redistribute it and/or modify |
; | it under the terms of the GNU Affero General Public License as |
; | published by the Free Software Foundation, either version 3 of the |
; | License, or (at your option) any later version. |
; | |
; | This program is distributed in the hope that it will be useful, |
; | but WITHOUT ANY WARRANTY; without even the implied warranty of |
; | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
; | GNU Affero General Public License for more details. |
; | |
; | You should have received a copy of the GNU Affero General Public License |
; | along with this program. If not, see <http://www.gnu.org/licenses/>. |
; ----------------------------------------------------------------------------
;
;QUIT
;
;
parseFilesInPath(path,extension,deep,docName,errorList,outputFile,outputPath)
;
n files,dirs,dir,error,ok
;
s extension=$g(extension) i extension="" s extension="*"
s docName=$g(docName) i docName'="" s docName="mgwTemp"
s outputPath=$g(outputPath)
i outputPath'="" s ok=$$makeDirectory(outputPath)
;
d getFilesInPath(path,extension,.files)
d processFiles(.files,path,.errorList,docName,$g(outputFile),$g(outputPath))
i '$g(deep) QUIT
;
d getDirectoriesInPath(path,.dirs)
s dir=""
f s dir=$o(dirs(dir)) q:dir="" d
. n dirPath
. s dirPath=path_"\"_dir
. d parseFilesInPath(dirPath,extension,deep,docName,.errorList)
Q
;
processFiles(files,path,errorList,docName,outputFile,outputPath)
;
n filename,filepath,error
;
s filename="",error=""
f s filename=$o(files(filename)) q:filename="" d
. s filepath=path_"\"_filename
. s error=$$processFile(filepath,docName,$g(outputFile),$g(outputPath))
. i error'="" s errorList(filepath)=error
QUIT
;
processFile(filepath,docName,outputFile,outputPath)
;
n dn,error,cspVars,phpVars
;
s outputPath=$g(outputPath)
i $$fileSize^%zewdAPI(filepath)=0 QUIT "empty file"
;i '$zu(140,1,filepath) QUIT "empty file"
i '$$fileExists^%zewdAPI(filepath) QUIT "missing file"
;i $zu(140,1,filepath)=-2 QUIT "missing file"
s error=$$parseFile(filepath,docName,.cspVars,.phpVars,1)
i error'="" QUIT error
i $g(outputFile)=1 d
. s outputPath=$g(outputPath)
. i outputPath'="" d q:error'=""
. . n rpath,fn
. . i $e(outputPath,$l(outputPath))'="\" s outputPath=outputPath_"\"
. . s rpath=$re(filepath)
. . s fn=$re($p(rpath,"\",1))
. . s outputPath=outputPath_fn
. . i '$$openNewFile^%zewdAPI(outputPath) s error="Unable to open output file "_outputPath q
. . ;o outputPath:"nw":1 e s error="Unable to open output file "_outputPath q
. . u outputPath
. d outputDOM(docName,,.cspVars,.phpVars)
. i $g(outputPath)'="" c outputPath
QUIT error
;
parseFile(filepath,docName,cspVars,phpVars,isHTML,maxLineLength)
;
n nlines,ok,%error
;
;
k %error
s %error=""
i $e(filepath,1)="^" d
. k ^CacheTempEWD($j)
. m ^CacheTempEWD($j)=filepath
e d i %error'="" QUIT %error
. s nlines=$$importFile(filepath,$g(maxLineLength))
. i nlines=-1 s %error="The file path "_filepath_" does not exist" q
. i nlines=0 s %error=filepath_" is an empty file" q
. i nlines=1,^CacheTempEWD($j,1)=$c(13,10) s %error=filepath_" is an empty file" q
d tokeniseCSPVariables(.cspVars)
d tokenisePHPVariables(.phpVars)
d normaliseDivs
i $g(isHTML)=2 d closeOptions s isHTML=1
s ok=$$openDOM^%zewdDOM(0,,,,,,,,,,,,,,,,,)
i ok'="" QUIT ok
s ok=$$removeDocument^%zewdDOM(docName,0,0)
s ok=$$closeDOM^%zewdDOM()
s %error=$$parseDocument($g(docName),$g(isHTML))
k ^CacheTempEWD($j)
QUIT %error
;
parseStream(streamName,docName,isHTML)
;
n error,file,filename,ok,x
s error=""
QUIT error
testHTTP ;
;
n docName,http,ok,stream
;
QUIT
;
;parseURL(server,getPath,docName,port,isHTML,responseTime,browserType,post,maxLineLength,headers)
parseURL(server,getPath,docName,port,isHTML,responseTime,browserType,post,maxLineLength,headers,sslHost,sslPort)
;
n bsig,endTime,error,file,filename,http,ok,startTime
;
s error=""
n cspVars,%error,html,phpVars,reqHeaders,respHeaders,url
i $e(getPath,1)'="/" s getPath="/"_getPath
;s url="http://"_server_getPath
;i $g(headers("Cookie"))'="" s reqHeaders(1)="Cookie: "_headers("Cookie")
;k headers
;i $g(responseTime)="" s responseTime=10
;s ok=$$httpGET^%zewdGTM(url,.html,.reqHeaders,responseTime,,,.headers)
i port'="" s getPath=":"_port_getPath
s http="http://"
i $g(sslPort)'="" s http="https://"
s url=http_server_getPath
i $g(headers("Cookie"))'="" s reqHeaders(1)="Cookie: "_headers("Cookie")
k headers
i $g(responseTime)="" s responseTime=10
s ok=$$httpGET^%zewdGTM(url,.html,.reqHeaders,responseTime,,,.headers,$g(sslHost),$g(sslPort))
;httpGET(url,html,headerArray,timeout,test,rawResponse,respHeaders,sslHost,sslPort)
k ^CacheTempEWD($j)
m ^CacheTempEWD($j)=html
d tokeniseCSPVariables(.cspVars)
d tokenisePHPVariables(.phpVars)
d normaliseDivs
s ok=$$openDOM^%zewdDOM(0,,,,,,,,,,,,,,,,,)
i ok'="" QUIT ok
s ok=$$removeDocument^%zewdDOM(docName,0,0)
s ok=$$closeDOM^%zewdDOM()
s %error=$$parseDocument($g(docName),$g(isHTML))
k ^CacheTempEWD($j)
QUIT error
;
importFile(filepath,maxLength)
;
n dlim,i,x,zt
;
k ^CacheTempEWD($j)
i $g(maxLength)="" s maxLength=10000
;i $zu(140,1,filepath)=-2 QUIT -1
i '$$fileExists^%zewdAPI(filepath) QUIT -1
c filepath
s i=$$gtmImportFile(filepath)
QUIT i-1
;
gtmImportFile(filepath)
n buf,buflen,i,len,lineNo,maxlen,x1,x2,xlen
o filepath:(readonly:stream:exception="g importNotExists")
u filepath:exception="g eof"
k ^CacheTempEWD($j)
s lineNo=1,buf="",maxlen=2000
f i=1:1 r x#maxlen d
. s x=$tr(x,$c(13),"")
. s x=$tr(x,$c(9)," ")
. s buflen=$l(buf)
. s xlen=$l(x)
. i (buflen+xlen)<maxlen s buf=buf_$c(10)_x q
. s len=maxlen-buflen
. s buf=buf_$e(x,1,len)
. s ^CacheTempEWD($j,lineNo)=$$replaceAll^%zewdAPI(buf,$c(10,10),$c(10))
. s buf=$e(x,len+1,$l(x))
. s lineNo=lineNo+1
eof ;
s ^CacheTempEWD($j,lineNo)=$$replaceAll^%zewdAPI(buf,$c(10,10),$c(10))_$c(10)
c filepath
QUIT i
;
importNotExists
s $zt=""
s i=-1
QUIT i
;
parseDocument(docName,isHTML)
;
; Extract each line from the document
;
i $g(isHTML)="" s isHTML=0
n buf,cspVars,dlim,docOID,doctype,elementName,%error,isSVG,%line,lineNo
n namespaceURI,nextLine,nLines,nodeOID,np,ntags,OIDArray,ok,%p1,%p2,%p3,%p4
n prevLine
;
k %error
;i '$$licensed^%eXtc("XPath") QUIT "You need a valid Lite or Full eXtc License to run the XHTML Parser"
s ok=$$openDOM^%zewdAPI()
i ok'="" QUIT ok
s (namespaceURI,elementName,doctype)=""
i docName'="" s ok=$$removeDocument^%zewdDOM(docName,0,0)
s docOID=$$createDocument^%zewdDOM(namespaceURI,elementName,doctype,.docName,)
;
s buf="",nextLine=1,isSVG=0
;
k ^CacheTempUserNode($j)
s ^CacheTempUserNode($j)=10000
;
; tidy up record boundaries
;
s nLines=$o(^CacheTempEWD($j,""),-1)
s dlim=$c(13,10)
i $$os^%zewdHTMLParser()="unix" s dlim=$c(10)
i $$os^%zewdHTMLParser()="gtm" s dlim=$c(10)
i $g(^CacheTempEWD($j,1))'[$c(13,10),$g(^CacheTempEWD($j,1))[$c(10) s dlim=$c(10)
i nLines>1 f lineNo=2:1:nLines d
. s %line=^CacheTempEWD($j,lineNo)
. s np=$l(%line,dlim)
. s %p1=$p(%line,dlim,1)
. s %p2=$p(%line,dlim,2,np)
. s prevLine=^CacheTempEWD($j,lineNo-1)_%p1
. s ^CacheTempEWD($j,lineNo-1)=prevLine
. s ^CacheTempEWD($j,lineNo)=%p2
. ;
. i $e(prevLine,$l(prevLine)-2,$l(prevLine))["<" d
. . i $e(prevLine,$l(prevLine))=dlim s prevLine=$e(prevLine,1,$l(prevLine)-1)
. . s nextLine=%p2
. . i %p2="" s nextLine=$g(^CacheTempEWD($j,lineNo+1))
. . s %p3=$p(nextLine,">",1)_">"
. . s %p4=$p(nextLine,">",2,10000)
. . s ^CacheTempEWD($j,lineNo-1)=prevLine_%p3
. . i %p2="" d
. . . s ^CacheTempEWD($j,lineNo+1)=%p4
. . e d
. . . s ^CacheTempEWD($j,lineNo)=%p4
;
s nextLine=1
f s %line=$$getLineFromBuffer(0,"",.buf,.nextLine) q:$$isOpenTag(%line)
s %error=""
d addChild(%line,docOID,docOID,.nextLine,.buf,.%error,.impliedClose,isHTML) ; finished !
;
; remove any ewdDummy nodes
;
set ntags=$$getTagsByName^%zewdCompiler("ewddummy",docName,.OIDArray)
set nodeOID=""
for set nodeOID=$order(OIDArray(nodeOID)) quit:nodeOID="" do
. do removeIntermediateNode^%zewdCompiler4(nodeOID)
;
s ok=$$closeDOM^%zewdDOM()
k ^CacheTempUserNode($j)
Q $g(%error)
;
addChild(%line,parentOID,docOID,nextLine,%buf,%error,impliedClose,isHTML)
;
n %attr,%text,%nextLine,%line2,childOID,i,%line3,tagName,%stop,isText,textArray,%xattr
;
s %stop=0
;
i $$os()="gtm" s $zt=""
f i=1:1 d q:%stop s %line=$$getLineFromBuffer(0,"",.%buf,.nextLine) q:%buf="" i i>16000 s %error="Unable to parse page just before "_$e(%buf,1,400)_$c(13,10)_"Hint : check for improperly matched <tr> and/or <td> tags" q
. s %text=""
. i $$isText(%line) d QUIT
. . i $$getTagName^%zewdDOM(parentOID)'="script" s %text=$$tidyText(%line)
. . i %text'="" d
. . . n textOID,textx
. . . i %text[$c(9) d q:%text=""
. . . . s %text=$$replaceAll^%zewdAPI(%text,$c(9)," ")
. . . . i $g(tagName)'="xsl:text" d ;DLW
. . . . . s textx=$$replaceAll^%zewdAPI(%text," "," ")
. . . . . i textx=" " s %text=""
. . . s textOID=$$createTextNode^%zewdDOM(%text,docOID)
. . . s textOID=$$appendChild^%zewdDOM(textOID,parentOID)
. . . s childOID=textOID
. s tagName=$$parseElement(%line,.%attr,.%error,.isHTML) i $g(%error)'="" s %stop=1 QUIT
. i tagName="select",$d(%attr("multiple")) s %attr("multiple")="multiple"
. ;b:tagName="span"
. i $$zcvt^%zewdAPI(tagName,"U")="!DOCTYPE" QUIT ; ignore
. i tagName="html" k %attr ; remove XHTML attributes
. i $$isCloseTag(%line) d q
. . n parentTagName
. . s parentTagName=$$getTagName^%zewdDOM(parentOID)
. . i tagName="/form",parentTagName="tr" d
. . . s tagName="/tr"
. . . s %buf="</form>"_%buf
. . i tagName="/table",parentTagName="tr" d
. . . s tagName="/tr"
. . . s %buf="</table>"_%buf
. . i tagName="/tr",parentTagName="td" d
. . . s tagName="/td"
. . . s %buf="</tr>"_%buf
. . ;i tagName["/div" break
. . i tagName=("/"_parentTagName) s %stop=1
. . i tagName=("/"_$$getTagName^%zewdDOM(childOID)),$$hasText(childOID) s %stop=0
. i $$empty(.%attr) d Q
. . s childOID=$$addTag(tagName,parentOID,docOID,.%attr) ; add empty tag
. i tagName="p" d pTagClosure(.%buf,nextLine,parentOID)
. i tagName="li" d liTagClosure(.%buf,nextLine,parentOID)
. i $$impliedClose(tagName,.%attr) d QUIT
. . s childOID=$$addTag(tagName,parentOID,docOID,.%attr) ; add tag but no children
. i $$isOpenTag(%buf) d Q
. . ; does the current tag have an implied close, or does the next tag imply a forced closure of the current one?
. . i $$impliedClose(tagName,.%attr)!($$forceClose(tagName,%buf)) d QUIT ; just add tag but dont add next as child
. . . s childOID=$$addTag(tagName,parentOID,docOID,.%attr) ; add tag but no children
. . ;
. . s %line2=$$getLineFromBuffer(0,"",.%buf,.nextLine)
. . s childOID=$$addTag(tagName,parentOID,docOID,.%attr) ; add tag and next add child
. . d addChild(%line2,childOID,docOID,.nextLine,.%buf,.%error,,isHTML) s childOID="" i $g(%error)'="" s %stop=1
. ;
. s isText=0 i tagName="script"!(tagName="style")!(tagName="textarea")!(tagName="csp:method")!(tagName="server")!(tagName="ewd:javascript") s isText=1
. s %line2=$$getLineFromBuffer(isText,tagName,.%buf,.nextLine,.textArray)
. s %text="" i %line2'="**mgwArray***",$$isText(%line2) s %text=%line2 i 'isText s %text=$$tidyText(%line2) ; text found for tag
. i tagName="!DOCTYPE" d QUIT
. . ; ignore for now
. k %xattr m %xattr=%attr
. s childOID=$$addTag(tagName,parentOID,docOID,.%attr,%text,.textArray) ;
. i '$$isText(%line2) s %buf=%line2_%buf QUIT
. ;
. i $$isOpenTag(%buf) d QUIT
. . i $$impliedClose(tagName,.%xattr)!($$forceClose(tagName,%buf)) QUIT ; just add tag but dont add next as child
. . s %line3=$$getLineFromBuffer(0,"",.%buf,.nextLine)
. . d addChild(%line3,childOID,docOID,.nextLine,.%buf,.%error,,$g(isHTML)) s childOID="" s:$g(%error)'="" %stop=1 QUIT
QUIT
;
hasChildren(nodeOID)
;
n childOID,hasChildElements,nodeType
;
s childOID="",hasChildElements=0
f s childOID=$$getNextChild^%zewdAPI(nodeOID,childOID) q:childOID="" d q:hasChildElements
. s nodeType=$$getNodeType^%zewdDOM(childOID)
. i nodeType=1 s hasChildElements=1 q
. i nodeType=3 s hasChildElements=1
QUIT hasChildElements
;
hasText(nodeOID)
;
n childOID,hasText,nodeType
;
s childOID="",hasText=0
f s childOID=$$getNextChild^%zewdAPI(nodeOID,childOID) q:childOID="" d q:hasText
. s nodeType=$$getNodeType^%zewdDOM(childOID)
. i nodeType=3,$$getData^%zewdDOM(childOID)'="" s hasText=1
QUIT hasText
;
tidyText(text)
;
i 'isHTML d QUIT text
. n dlim,xtext
. s dlim=""
. i text[$c(13,10) s dlim=$c(13,10)
. i dlim="",text[$c(10) s dlim=$c(10)
. i dlim="" d
. . n os
. . s dlim=$c(10)
. . s os=$$os^%zewdHTMLParser()
. . i os="windows" s dlim=$c(13,10)
. s xtext=$$replaceAll^%zewdAPI(text,dlim,"")
. i $g(tagName)'="xsl:text" s xtext=$$replaceAll^%zewdAPI(xtext," ","") ; DLW
. i xtext="" s text="" q
. i dlim'="" d
. . n np,stop
. . s np=$l(text,dlim)
. . i np=3,$p(text,dlim,1)="" s text=$p(text,dlim,2) q
. . i $p(text,dlim,1)="" s text=$p(text,dlim,2,2000)
. . s stop=0
. . f i=np:-1:1 d q:stop
. . . i $p(text,dlim,i)'="" s stop=1 q
. . . s text=$p(text,dlim,1,i-1)
i text[$c(13,10) s text=$tr(text,$c(13,10),"")
i text[$c(10) s text=$tr(text,$c(10),"")
s text=$$stripSpaces^%zewdAPI(text)
;s text=$ZSTRIP(text,"<W")
;s text=$ZSTRIP(text,">W")
s text=$$replaceAll(text,"<","<")
s text=$$replaceAll(text,">",">")
Q text
;
replaceAll(InText,FromStr,ToStr) ; Replace all occurrences of a substring
;
n %p
;
s %p=InText
f q:%p'[FromStr S %p=$$replace(%p,FromStr,ToStr)
QUIT %p
;
replace(InText,FromStr,ToStr) ; replace old with new in string
;
n %p1,%p2
;
i InText'[FromStr q InText
s %p1=$p(InText,FromStr,1),%p2=$p(InText,FromStr,2,255)
QUIT %p1_ToStr_%p2
;
empty(%attr)
QUIT $d(%attr("/"))
;
impliedClose(tagName,attr)
;
n impliedClose,i,%line
;
i $e(tagName,1)="?" QUIT 1
;
s impliedClose=0
f i=1:1 s %line=$t(impliedCloseTags+i^%zewdCompiler15) q:%line["***END***" d q:impliedClose
. i tagName=$p(%line,";;",2) s impliedClose=1
;
; user defined implied closure tags
;
i impliedClose QUIT 1
;
QUIT $$isImpliedCloseTag^%zewdCompiler(tagName)
;
;
forceClose(tagName,%buf)
;
n %nextTag
;
s %nextTag=$p(%buf,">",1)
i tagName="tr",%nextTag="<tr" QUIT 1
i tagName="td",%nextTag="<td" QUIT 1
QUIT 0
;
addTag(tagName,parentOID,docOID,%attr,%text,textArray)
;
n commentOID,childOID,dummyOID,procInsOID,attrName,attrValue,eOID,parentTagName
;
s parentTagName=$$getTagName^%zewdDOM(parentOID)
;i tagName=parentTagName d
;. n count
;. s count=$increment(^CacheTempUserNode($j))
;. s tagName="ewdTag"_count_tagName break
i $d(textArray) d QUIT eOID
. n lineNo
. s eOID=$$createElement^%zewdDOM(tagName,docOID)
. s attrName=""
. f s attrName=$o(%attr(attrName)) q:attrName="" d
. . s attrValue=%attr(attrName)
. . d setAttribute^%zewdDOM(attrName,attrValue,eOID)
. s eOID=$$appendChild^%zewdDOM(eOID,parentOID)
. s lineNo=""
. f s lineNo=$o(textArray(lineNo)) q:lineNo="" d
. . n textOID,tOID
. . s textOID=$$createTextNode^%zewdDOM(textArray(lineNo),docOID)
. . s tOID=$$appendChild^%zewdDOM(textOID,eOID)
;
i $e(tagName,1)="?" d QUIT procInsOID
. n target,data
. s target=$p(tagName,"?",2)
. i target[$c(13,10) s target=$tr(target,$c(13,10),"")
. i target[$c(10) s target=$tr(target,$c(10),"")
. s data=$g(%attr("content"))
. i target="=" d
. . s target="php"
. . s data="echo("_data_");"
. s procInsOID=$$createProcessingInstruction^%zewdDOM(target,data,docOID)
. s procInsOID=$$appendChild^%zewdDOM(procInsOID,parentOID)
;
i tagName["CDATA" d QUIT commentOID
. n data
. s data=%attr("content")
. i data="" s data=" "
. s commentOID=$$createCDATASection^%zewdDOM(data,docOID)
. s commentOID=$$appendChild^%zewdDOM(commentOID,parentOID)
;
i tagName="!--" d QUIT commentOID
. n data
. s data=%attr("content")
. i data="" s data=" "
. s commentOID=$$createComment^%zewdDOM(data,docOID)
. s commentOID=$$appendChild^%zewdDOM(commentOID,parentOID)
;
i $g(%text)[$c(9) d
. n textx
. s %text=$$replaceAll^%zewdAPI(%text,$c(9)," ")
. s textx=$$replaceAll^%zewdAPI(%text," "," ")
. i textx=" " s %text=""
s childOID=$$addElementToDOM^%zewdDOM(tagName,parentOID,,.%attr,$g(%text))
QUIT childOID
;
isOpenTag(%line)
;f q:$e(%line,1)?1ANP d
;. s %line=$e(%line,2,$l(%line))
i $e(%line,1)'="<" QUIT 0
i $e(%line,2)="/" QUIT 0
QUIT 1
;
isCloseTag(%line)
i $e(%line,1,2)="</" QUIT 1
QUIT 0
;
isText(%line)
i $e(%line,1,2)="<<" QUIT 1
QUIT $e(%line,1)'="<"
;
displayTag(tagName,%attr)
;
n %name,%empty
;
w "<"_tagName
i tagName="!--" w %attr("content")_">" q
s %name="",%empty=0
f s %name=$o(%attr(%name)) q:%name="" d
. i %name="/" s %empty=1 q
. w " "_%name_"='"_%attr(%name)_"'"
i %empty w " /"
w ">"
w %line
Q
;
tokeniseCSPVariables(cspVars)
;
n line,lineNo,symbolNo
;
s lineNo="",symbolNo=$o(cspVars(""),-1)+1
;f s lineNo=$o(^%work($j,lineNo)) q:lineNo="" d
f s lineNo=$o(^CacheTempEWD($j,lineNo)) q:lineNo="" d
. ;s line=^%work($j,lineNo)
. s line=^CacheTempEWD($j,lineNo)
. f q:line'["#(" d
. . n %p1,%p2,%p3,nVars,symbol
. . s nVars=$l(line,"#(")
. . s %p1=$p(line,"#(",1)
. . s %p3=$p(line,"#(",2,nVars)
. . i %p3'[")#" d
. . . ;line buffer boundary - readjust
. . . n lineNo2,line2,%p4,%p5,npieces
. . . s lineNo2=lineNo+1
. . . ;s line2=$g(^%work($j,lineNo2))
. . . s line2=$g(^CacheTempEWD($j,lineNo2))
. . . q:line2=""
. . . s %p4=$p(line2,")#",1)_")#"
. . . s npieces=$l(line2,")#")
. . . s %p5=$p(line2,")#",2,npieces+2)
. . . s line=line_%p4
. . . s %p3=%p3_%p4
. . . ;s ^%work($j,lineNo2)=%p5
. . . s ^CacheTempEWD($j,lineNo2)=%p5
. . s %p2=$p(%p3,")#",1)
. . s %p3=$p(%p3,")#",2,1000)
. . s symbolNo=symbolNo+1
. . s symbol="&cspVar;"_symbolNo_"&cspVar;"
. . s line=%p1_symbol_%p3
. . s cspVars(symbolNo)=%p2
. ;s ^%work($j,lineNo)=line
. s ^CacheTempEWD($j,lineNo)=line
;
QUIT
;
normaliseDivs
;
n c,i,len,line,lineNo,nDiv,ndivClose,p1,p2,stop,tag
;
s lineNo=""
f tag="</div>","</span>","</table>","</ewd:foreach>","</ewd:if>" d
. f s lineNo=$o(^CacheTempEWD($j,lineNo)) q:lineNo="" d
. . s line=^CacheTempEWD($j,lineNo)
. . s line=$$lcSubstring^%zewdCompiler20(line,tag)
. . q:line'[tag
. . s ndivClose=$l(line,tag)
. . q:ndivClose<3
. . s len=$l(tag)-1
. . f nDiv=1:1:ndivClose d
. . . s p1=$p(line,tag,1,nDiv)
. . . s p2=$p(line,tag,(nDiv+1),2000)
. . . s stop=0
. . . f i=1:1 d q:stop
. . . . s c=$e(p2,i)
. . . . i c=$c(13)!(c=$c(10))!(c=" ")!(c=$c(9)) q
. . . . i c'="<" s stop=1 q
. . . . s line=p1_"<ewddummy />"_tag_"<ewddummy />"_p2 s stop=1
. . s ^CacheTempEWD($j,lineNo)=line
QUIT
;
closeOptions
;
n line,lineNo
;
s lineNo="",skip=0
f s lineNo=$o(^CacheTempEWD($j,lineNo)) q:lineNo="" d
. s line=^CacheTempEWD($j,lineNo)
. s line=$e(line,skip+1,$l(line))
. i $d(^CacheTempEWD($j,lineNo+1)) d
. . s line2=^CacheTempEWD($j,lineNo+1)
. . s p1=$p(line2,"</",1)
. . s p2=$p(line2,"</",2,3)
. . s p2=$$zcvt^%zewdAPI(p2,"l")
. . i $e(p2,1,6)'="option" d q
. . . s line=line_p1
. . . s skip=$l(p1)
. . s p1=$p(line2,"</",1,2)
. . s p2=$p(line2,"</",3)
. . s line=line_p1
. . s skip=$l(p1)
. i $$zcvt^%zewdAPI(line,"l")["<option" d
. . s buf=line
. . s line=""
. . f q:$$zcvt^%zewdAPI(buf,"l")'["<option" d
. . . s buf=$$convertSubstringCase(buf,"<option","l")
. . . s p1=$p(buf,"<option",1)
. . . s p2=$p(buf,"<option",2,10000)
. . . s p3=$p(p2,"<",1)
. . . i $e(p3,$l(p3)-1,$l(p3))=$c(13,10) s p3=$e(p3,1,$l(p3)-2)
. . . s p1=p1_"<option"_p3
. . . s len=$l(p1)
. . . s p1=p1_"</option>"
. . . s line=line_p1
. . . s buf=$e(buf,len+1,$l(buf))
. . s line=line_buf
. ;
. s ^CacheTempEWD($j,lineNo)=line
QUIT
;
tokenisePHPVariables(phpVars)
;
n lineNo,sig,varNo
;
s lineNo="",varNo=$o(phpVars(""),-1)+1
f s lineNo=$o(^CacheTempEWD($j,lineNo)) q:lineNo="" d
. f sig="?","%" d tokenise(sig,.varNo,lineNo)
QUIT
;
tokenise(sig,varNo,lineNo)
;
; sig is ? for PHP, % for JSP
; <?= #var ?> : direct substitution (dangerous but for backward compatibility)
; <?h #var ?> : HTML encoded substitution
; <?j #var ?> : Javascript encoded substitution
; <?u #var ?> : URL encoded substitution
;
; phpVars(no,"esc")=h|j|u to ensure compiler adds correct escaping around value
;
n i,line,lineB4,str1,strx,str2
;
s str1="<"_sig,str2=sig_">"
f i="=","h","j","u" s strx(i)=str1_i
s line=^CacheTempEWD($j,lineNo)
s lineB4=line
f i="=","h","j","u" d
. s str1=strx(i)
. s line=$$tokeniseLine(line,.varNo,i,lineNo,str1,str2)
i line'=lineB4 s ^CacheTempEWD($j,lineNo)=line
QUIT
;
tokeniseLine(line,varNo,type,lineNo,str1,str2)
;
n p1,p2,p3,p4
;
f q:line'[str1 d
. s varNo=varNo+1
. s p1=$p(line,str1,1)
. s p2=$p(line,str1,2,500)
. i p2'[str2 d
. . n line2
. . s line2=$g(^CacheTempEWD($j,lineNo+1))
. . i line2'="" d
. . . n c1,c2,np
. . . s np=$l(line2,">")
. . . s c1=$p(line2,">",1)_">"
. . . s c2=$p(line2,">",2,np+2)
. . . s line=line_c1
. . . s p2=p2_c1
. . . s ^CacheTempEWD($j,lineNo+1)=c2
. s p3=$p(p2,str2,1)
. s p4=$p(p2,str2,2,500)
. s phpVars(varNo)=p3
. s phpVars(varNo,"esc")=type
. s line=p1_"&php;"_varNo_"&php;"_p4
QUIT line
;
pTagClosure(buf,nextLine,parentOID)
;
; look ahead in buffer. If we find an explicit </p> tag with no <p>
; tags before it, then we'll leave it alone.
;
; If we can't find any </p> tags at all, and no other <p> tags, then leave it alone and let the parser close it off at the end
;
; If we find another <p> tag before a </p> tag, then insert a </p> tag before the next <p> tag
;
n buflc,openPPos1,openPPos2,buf2,lineNo,%stop,closePos,parentTag,closePos2,nextPFound,openPos
;
s lineNo="",nextPFound=0
s closePos=$f($$zcvt^%zewdAPI(buf,"L"),"</p>")
s openPPos1=$f($$zcvt^%zewdAPI(buf,"L"),"<p>")
s openPPos2=$f($$zcvt^%zewdAPI(buf,"L"),"<p ")
i openPPos1>0,openPPos1<closePos s nextPFound=1
i openPPos2>0,openPPos2<closePos s nextPFound=1
s openPos=""
i openPPos1>0 s openPos=openPPos1
i openPPos2>0,openPPos2<openPos s openPos=openPPos2
i closePos=0,openPos'="" s nextPFound=1
s parentTag=$$getTagName^%zewdDOM(parentOID)
s closePos2=$f($$zcvt^%zewdAPI(buf,"L"),"</"_parentTag)
i closePos2>0,closePos>0,closePos2<closePos s closePos=closePos2 i closePos<openPos d closeP(parentTag,.buf) QUIT
;i closePos=0,closePos2>0 s closePos=closePos2 i closePos<openPos d closeP(parentTag,.buf) QUIT
i closePos=0,closePos2>0 s closePos=closePos2 i closePos<openPos!(openPos="") d closeP(parentTag,.buf) QUIT
;
i closePos>0,'nextPFound QUIT ; matching </p> found for current <p>
;
i nextPFound d
. n str,strx,len
. s str=$e(buf,1,openPos)
. s strx=$re(str)
. s strx=$$convertSubstringCase(strx,"p<")
. s strx=$p(strx,"p<",2)
. s str=$re(strx)
. s len=$l(str)
. s buf=str_"</p>"_$e(buf,len+1,$l(buf))
.
; check in the rest of the buffer lines
s %stop=0
i closePos=0 d
. s lineNo=nextLine-1
. ;f s lineNo=$o(^%work($j,lineNo)) q:lineNo="" d q:%stop
. f s lineNo=$o(^CacheTempEWD($j,lineNo)) q:lineNo="" d q:%stop
. . ;s buf2=^%work($j,lineNo)
. . s buf2=^CacheTempEWD($j,lineNo)
. . s closePos=$f($$zcvt^%zewdAPI(buf2,"L"),"</p>")
. . s openPPos1=$f($$zcvt^%zewdAPI(buf2,"L"),"<p>")
. . s openPPos2=$f($$zcvt^%zewdAPI(buf2,"L"),"<p ")
. . i openPPos1>0,openPPos1<closePos s nextPFound=1
. . i openPPos2>0,openPPos2<closePos s nextPFound=1
. . s openPos=""
. . i openPPos1>0 s openPos=openPPos1
. . i openPPos2>0,openPPos2<openPos s openPos=openPPos2
. . ;
. . i closePos>0,'nextPFound s %stop=1 q
. . i closePos>0,nextPFound d q
. . . n str,strx,len
. . . s str=$e(buf2,1,openPos)
. . . s strx=$re(str)
. . . s strx=$$convertSubstringCase(strx,"p<")
. . . s strx=$p(strx,"p<",2)
. . . s str=$re(strx)
. . . s len=$l(str)
. . . s buf2=str_"</p>"_$e(buf2,len+1,$l(buf2))
. . . ;s ^%work($j,lineNo)=buf2
. . . s ^CacheTempEWD($j,lineNo)=buf2
. . . s %stop=1
;
QUIT
;
closeP(tagName,buf)
n findStr,%p1,%p2
s findStr="</"_tagName_">"
s %p1=$p(buf,findStr,1)
s %p2=$p(buf,findStr,2,5000)
s buf=%p1_"</p>"_findStr_%p2
QUIT
;
liTagClosure(buf,nextLine,parentOID)
;
; look ahead in buffer. If we find an explicit </li> tag with no <li>
; tags before it, then we'll leave it alone.
;
; If we can't find any </li> tags at all, and no other <li> tags, then leave it alone and let the parser close it off at the end
;
; If we find another <li> tag before a </li> tag, then insert a </li> tag before the next <li> tag
; If we find a <ul> before the next <li> then leave the current one alone
;
n buf2,buflc,closePos,closePos2,closeULPos,lineNo,nextPFound,openPos
n openPPos1,openPPos2,openULPos,openULPos1,openULPos2,parentTag,%stop
;
s lineNo="",nextPFound=0
s closePos=$f($$zcvt^%zewdAPI(buf,"L"),"</li>")
s openPPos1=$f($$zcvt^%zewdAPI(buf,"L"),"<li>")
s openPPos2=$f($$zcvt^%zewdAPI(buf,"L"),"<li ")
s openULPos1=$f($$zcvt^%zewdAPI(buf,"L"),"<ul>")
s openULPos2=$f($$zcvt^%zewdAPI(buf,"L"),"<ul ")
s closeULPos=$f($$zcvt^%zewdAPI(buf,"L"),"</ul>")
s openULPos=0
i openULPos1>0 s openULPos=openULPos1
i openULPos=0,openULPos2>0 s openULPos=openULPos2
i openULPos1>0,openULPos2>0,openULPos2<openULPos s openULPos=openULPos2
;
i openPPos1>0,openPPos1<closePos s nextPFound=1
i openPPos2>0,openPPos2<closePos s nextPFound=1
s openPos=""
i openPPos1>0 s openPos=openPPos1
i openPPos2>0,openPPos2<openPos s openPos=openPPos2
i closePos=0,openPos'="" s nextPFound=1
;
i openULPos'=0,openPos'="",openULPos<openPos QUIT
;i closeULPos'=0,openPos'="",closeULPos<openPos QUIT
;
s parentTag=$$getTagName^%zewdDOM(parentOID)
s closePos2=$f($$zcvt^%zewdAPI(buf,"L"),"</"_parentTag)
i closePos2>0,closePos>0,closePos2<closePos s closePos=closePos2 i closePos<openPos d closeLI(parentTag,.buf) QUIT
i closePos=0,closePos2>0 s closePos=closePos2 i closePos<openPos!(openPos="") d closeLI(parentTag,.buf) QUIT
;
i closePos>0,'nextPFound QUIT ; matching </p> found for current <p>
;
i nextPFound d
. n str,strx,len
. s str=$e(buf,1,openPos)
. s strx=$re(str)
. s strx=$$convertSubstringCase(strx,"il<")
. s strx=$p(strx,"il<",2)
. s str=$re(strx)
. s len=$l(str)
. s buf=str_"</li>"_$e(buf,len+1,$l(buf))
.
; check in the rest of the buffer lines
s %stop=0
i closePos=0 d
. s lineNo=nextLine-1
. ;f s lineNo=$o(^%work($j,lineNo)) q:lineNo="" d q:%stop
. f s lineNo=$o(^CacheTempEWD($j,lineNo)) q:lineNo="" d q:%stop
. . ;s buf2=^%work($j,lineNo)
. . s buf2=^CacheTempEWD($j,lineNo)
. . s closePos=$f($$zcvt^%zewdAPI(buf2,"L"),"</li>")
. . s openPPos1=$f($$zcvt^%zewdAPI(buf2,"L"),"<li>")
. . s openPPos2=$f($$zcvt^%zewdAPI(buf2,"L"),"<li ")
. . s openULPos1=$f($$zcvt^%zewdAPI(buf,"L"),"<ul>")
. . s openULPos2=$f($$zcvt^%zewdAPI(buf,"L"),"<ul ")
. . s openULPos=0
. . i openULPos1>0 s openULPos=openULPos1
. . i openULPos=0,openULPos2>0 s openULPos=openULPos2
. . i openULPos1>0,openULPos2>0,openULPos2<openULPos s openULPos=openULPos2
. . i openPPos1>0,openPPos1<closePos s nextPFound=1
. . i openPPos2>0,openPPos2<closePos s nextPFound=1
. . s openPos=""
. . i openPPos1>0 s openPos=openPPos1
. . i openPPos2>0,openPPos2<openPos s openPos=openPPos2
. . ;
. . i closePos>0,'nextPFound s %stop=1 q
. . ;
. . i openULPos'=0,openPos'="",openULPos<openPos s %stop=1 q
. . ;
. . i closePos>0,nextPFound d q
. . . n str,strx,len
. . . s str=$e(buf2,1,openPos)
. . . s strx=$re(str)
. . . s strx=$$convertSubstringCase(strx,"il<")
. . . s strx=$p(strx,"il<",2)
. . . s str=$re(strx)
. . . s len=$l(str)
. . . s buf2=str_"</li>"_$e(buf2,len+1,$l(buf2))
. . . ;s ^%work($j,lineNo)=buf2
. . . s ^CacheTempEWD($j,lineNo)=buf2
. . . s %stop=1
;
QUIT
;
closeLI(tagName,buf)
n findStr,%p1,%p2
s findStr="</"_tagName_">"
s %p1=$p(buf,findStr,1)
s %p2=$p(buf,findStr,2,5000)
s buf=%p1_"</li>"_findStr_%p2
QUIT
;
getLineFromBuffer(isText,tagName,buf,nextLine,textArray)
;
n maxLine,stop
k textArray
s maxLine=$o(^CacheTempEWD($j,""),-1)
s stop=0
f d q:stop
. i $g(^CacheTempEWD($j,nextLine))'="" s stop=1 q
. s nextLine=nextLine+1
. i nextLine>maxLine s stop=1 q
i $l(buf)<2000,$d(^CacheTempEWD($j,nextLine)) d
. s buf=buf_^CacheTempEWD($j,nextLine)
. s nextLine=nextLine+1
;
i isText d
. n buf1
. ;s buf1=$zstrip(buf,"<>W")
. s buf1=$$stripSpaces^%zewdAPI(buf)
. i $e(buf1,1,2)=$c(13,10) d
. . s buf1=$e(buf1,3,$l(buf1))
. . ;s buf1=$zstrip(buf1,"<>W")
. . s buf1=$$stripSpaces^%zewdAPI(buf1)
. e d
. . i $e(buf1,1)=$c(10) d
. . . s buf1=$e(buf1,2,$l(buf1))
. . . ;s buf1=$zstrip(buf1,"<>W")
. . . s buf1=$$stripSpaces^%zewdAPI(buf1)
. i $e(buf1,1,10)["<ewd:" s isText=0
i isText QUIT $$getScriptText(.buf,tagName,.nextLine,.textArray)
i $e(buf,1,4)="<!--" QUIT $$getCommentText(.buf)
i $e(buf,1)="<" QUIT $$getTagFromBuffer(.buf)
QUIT $$getTextFromBuffer(.buf,.nextLine,.textArray)
;
getCommentText(buf)
;
n text
;
s text=$p(buf,"-->",1)_"-->"
s buf=$p(buf,"-->",2,1000)
;
QUIT text
;
getCDATAText(buf)
;
n text
;
s text=$p(buf,"]]>",1)_"]]>"
s buf=$p(buf,"]]>",2,1000)
;
QUIT text
;
;
getScriptText(buf,tagname,nextLine,textArray)
;
n %c,c8,%len,n,%stop,text
;
s c8="",text="",%stop=0
s %len=$l(tagname)+2
;i buf'[("</"_tagname) d
i $$zcvt^%zewdAPI(buf,"l")'[("</"_$$zcvt^%zewdAPI(tagname,"l")) d
. ;i $g(^%work($j,nextLine))'="" d
. i $g(^CacheTempEWD($j,nextLine))'="" d
. . n line,%p1,npieces
. . ;s line=^%work($j,nextLine)
. . s line=^CacheTempEWD($j,nextLine)
. . i line'[("</"_tagname_">") d
. . . s textArray(1)=buf,n=1,buf="",%stop=0
. . . f nextLine=nextLine:1 d q:%stop
. . . . s line=$g(^CacheTempEWD($j,nextLine))
. . . . i line="" s %stop=1 q
. . . . i line[("</"_tagname_">") s %stop=1 q
. . . . s n=n+1
. . . . s textArray(n)=line
. . s %p1=$p(line,("</"_tagname_">"),1)
. . i ($l(buf)+$l(%p1))>4000 d
. . . n %dlim,%no,%np,%p2,%p3
. . . s %dlim=$c(13,10)
. . . i %p1'[%dlim,%p1[$c(10) s %dlim=$c(10)
. . . s %p2=$p(%p1,%dlim,1)
. . . s %np=$l(%p1,%dlim)
. . . s %p3=$p(%p1,%dlim,2,%np)
. . . s buf=buf_%p2
. . . s %no=$o(textArray(""),-1)+1
. . . s textArray(%no)=buf
. . . s buf=%p3
. . . s %p1=""
. . . i buf["*/ewd:comment" d
. . . . n %p10,%p11
. . . . s %p10=$p(buf,"*/ewd:comment",1)
. . . . i %p10'["/*ewd:comment" d
. . . . . s %p11=$p(buf,"*/ewd:comment",2,10000)
. . . . . s buf=%p11
. . s buf=buf_%p1_("</"_tagname_">")
. . s npieces=$l(line,("</"_tagname_">"))
. . s line=$p(line,("</"_tagname_">"),2,npieces+2)
. . ;s ^%work($j,nextLine)=line
. . s ^CacheTempEWD($j,nextLine)=line
s %stop=0
f q:%stop d
. s %c=$e(buf,1)
. s c8=c8_%c,c8=$re(c8),c8=$e(c8,1,%len),c8=$re(c8)
. i $$zcvt^%zewdAPI(c8,"L")=("</"_tagname) d q
. . s %stop=1
. . s buf="</"_$e(tagname,1,$l(tagname)-1)_buf
. . s text=$e(text,1,$l(text)-(%len-1))
. s text=text_%c
. s buf=$e(buf,2,$l(buf))
;
i $d(textArray) d
. n lastLine
. s lastLine=$o(textArray(""),-1)+1
. s textArray(lastLine)=text
. s text="**mgwArray***"
QUIT text
;
getTagFromBuffer(buf)
;
n %line,%c,%stop,%sapos,%dapos,%inSingleQuotedString,%inDoubleQuotedString,%inQuotedString,%inVar
n %firstQuoteType
;
s %stop=0
s %line=""
s %sapos="'"
s %dapos=""""
s %inSingleQuotedString=0
s %inDoubleQuotedString=0
s %firstQuoteType=""
s %inVar=0
;
f s %c=$$extractChar(.buf) q:%c="" d q:%stop
. n %c2
. s %c2=$e(buf,1)
. i %c="#",%c2="(" s %inVar=1
. i %c=")",%c2="#" s %inVar=0