Stackinator Script

[restcoser]

Hey all,
For the map editors: I made a small cube script that allows to rapidly paste copied segments and stack them.
For using it: After executing the script, copy something, then select where you want to stack it. Rightclick the side of the selection you want to do the stack in.
Press V and scroll.
Works properly as well for copied elements multiple cubes deep.
Works really well for making columns from circles and many other things.

v_is_pressed = 0; v_stacking = 0;
stack_selboxsize_x = 0//will be set after copying
stack_selboxsize_y = 0//
stack_selboxsize_z = 0//
orig_selorient = 0
stack_sel_instead = 0 //if you want to stack what you have currently selected, instead of stacking your copy-buffer, set this to 1. Uses the copy-buffer.
setcomplete stack_sel_instead 1

editbind V [
	v_is_pressed = 1
	orig_selorient = $selorient 		//the paste function (mostly just pastehilight...) can change the selection box orientation, so saving it 
	if ($stack_sel_instead) [
		stack_selboxsize_x = (getenginestat 30); stack_selboxsize_y = (getenginestat 31); stack_selboxsize_z = (getenginestat 32) //for selection unstacking
	]
	////////retain original V editpaste function
		cancelpaste = (! || [enthavesel] [havesel])
		if (=s "" $entcopybuf) [if (! $stack_sel_instead) pastehilight] [entrepl; if $cancelpaste [cancelsel]] //pastehilight is incompatible with selection stacking
	////////end of editpaste

	onrelease [
		if (! $v_stacking) [
		
			////////retain original V editpaste function onrelease
				if (=s "" $entcopybuf) [
					if $opaquepaste delcube
					paste
					entpaste
					if $cancelpaste [cancelsel]
				]
			////////end of editpaste onrelease
		] [v_stacking = 0]
		
		v_is_pressed = 0
	]
]

editbind C [
  	//get selection details to stack correctly if the copy is more than 1 deep
	stack_selboxsize_x = (getenginestat 30); stack_selboxsize_y = (getenginestat 31); stack_selboxsize_z = (getenginestat 32)
	
	editcopy
]
getorientxyz = [
	orientstat = $selorient
	? (< $orientstat 2) x (? (< $orientstat 4) y z)	
]
stackonce = [
	if ($stack_sel_instead) [ //copy the selection
		//get selection details to stack correctly if the copy is more than 1 deep
		stack_selboxsize_x = (getenginestat 30); stack_selboxsize_y = (getenginestat 31); stack_selboxsize_z = (getenginestat 32)
		copy
	]
	stack_universaldeltacount = (? (& $selorient 1) 1 $[stack_selboxsize_@(getorientxyz)])
	selorient $orig_selorient; 	//restore original orientation which pastehilight might change
	loop i $stack_universaldeltacount [editface -1 1; delcube]
	v_stacking = 1
	paste 				//first paste to select all cubes where pasting will happen
	delcube 			//delete the area so the entire paste area is cleared
	paste
]
unstackonce = [
	selorient $orig_selorient; 	//return orientation that was present before V was pressed	
	loop i $[stack_selboxsize_@(getorientxyz)] [air; editface 1 1]
	v_stacking = 1
]
editbind MOUSE5 [ 
	if (v_is_pressed) [stackonce] [universaldelta -1]
]
editbind MOUSE4 [
	if (v_is_pressed) [unstackonce] [universaldelta 1]
] 

stack = [loop i $arg1 stackonce]; setcomplete stack 1;

Edit: v2. Now you can "unstack" (delete by scrolling in the other direction). You can also set it to work based on what you select, not what is in your copy buffer. (it will just copy what you have selected when you start stacking) Set "stack_sel_instead = true" for this. Small function for stacking exact amounts. Overall cleaner script.