bosk.maven-publish.gradle

/*
 * Settings related to publishing Maven artifacts.
 * Actual technological dependencies of Bosk should go into the project's Gradle files.
 */

plugins {
	id 'java-library'
	id 'maven-publish'
	id 'signing'
}


java {
	withSourcesJar()
	withJavadocJar()
}

jar {
	manifest {
		// https://docs.gradle.org/current/userguide/building_java_projects.html#sec:jar_manifest
		attributes("Implementation-Version": archiveVersion)
	}
}

publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
			versionMapping {
				usage('java-api') {
					fromResolutionOf('runtimeClasspath')
				}
				usage('java-runtime') {
					fromResolutionResult()
				}
			}
			pom {
				name = 'Bosk'
				packaging = 'jar'
				description = 'Control plane state management library'
				url = 'http://bosk.works'
				licenses {
					license {
						name = 'The Apache License, Version 2.0'
						url = 'https://www.apache.org/licenses/LICENSE-2.0.txt'
					}
				}
				developers {
					developer {
						id = 'pdoyle'
						name = 'Patrick Doyle'
						email = 'p.r.doyle@gmail.com'
					}
					developer {
						id = 'gjohnson'
						name = 'Grady Johnson'
						email = 'gradycsjohnson@gmail.com'
					}
				}
				scm {
					connection = 'scm:git:git://github.com/boskworks/bosk.git'
					developerConnection = 'scm:git:ssh://github.com:boskworks/bosk.git'
					url = 'https://github.com/boskworks/bosk'
				}
			}
		}
	}
	repositories {
		maven {
			def releasesRepoUrl = 'https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/'
			def snapshotsRepoUrl = 'https://s01.oss.sonatype.org/content/repositories/snapshots/'
			url version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl

			credentials {
				username = project.properties['ossrhUsername'] ?: 'bogusUser'
				password = project.properties['ossrhPassword'] ?: 'bogusPassword'
			}
		}
	}
}

signing {
	sign publishing.publications.mavenJava
	def signingKey = findProperty("signingKey")
	def signingPassword = findProperty("signingPassword")
	useInMemoryPgpKeys(signingKey, signingPassword)
}

javadoc {
	failOnError = false
	if(JavaVersion.current().isJava9Compatible()) {
		options.addBooleanOption('html5', true)
	}
}