Aligning printed text to the right

[ZivojinM]

Hello! I'm a very new at tinkering with this and I managed to get my 128*64 OLED work nice with the u8g2 library. In my sketch I have two numbers that are being calculated and printed on the screen. For aesthetic sake, I'd like them to be aligned to the right, as I think it looks nicer when they change from single to double digits by adding a number to the left of the first one.

I am using two separate counters being printed on two locations on the screen, one font used is u8g2_font_pxplusibmvga8_mn and another is u8g2_font_logisoso26_tn if that is of any importance. Thanks for the help!

[olikraus]

1. Convert the number to a string 's'
2. Use the following code to draw a right aligned string at position (x,y)

u8g2.drawStr(x-u8g2.GetStrWidth(s), y, s);

https://github.com/olikraus/u8g2/wiki/u8g2reference#getstrwidth

[ZivojinM]

Thank you for the reply! But I am struggling a bit to convert a number into a string since I'm using (in my test example, to see how the screen looks) generated numbers, millis countdown. So the print is printing these numbers, how would I convert them to a string? Sorry for bothering with basic questions.

void loop(void) {
        u8g2.firstPage();
        do { 
        u8g2.setFont(u8g2_font_logisoso26_tn);
        u8g2.setCursor(34, 36);
        u8g2.println(100 - (millis()/100)%101);
        if ((millis()/100)%101 == 100);
        } while ( u8g2.nextPage() );      
}

[olikraus]

Not tested:

void loop(void) {
        int x = 100 - (millis()/100)%101;
        String xs = String(x);
        u8g2.firstPage();
        do { 
           u8g2.setFont(u8g2_font_logisoso26_tn);
           u8g2.setCursor(34-u8g2.getStrWidth(xs.c_str()), 36);
           u8g2.println(xs.c_str());
        } while ( u8g2.nextPage() );      
}

Reference: https://www.arduino.cc/reference/en/language/variables/data-types/stringobject/

Edit: fixed "getStrWidth"

[ZivojinM]

Just fixed "getStrWidth" (lowercase get instead of Get in your example) and used a font from "fntlistmono" - works perfect! Thank you very much!

[Chemita23]

I solved this by this way:

#include <Arduino.h>
#include <U8g2lib.h>
#include <SPI.h>
#include <Wire.h>

#define OLED_MOSI   22
#define OLED_CLK   18
#define OLED_DC    16
#define OLED_CS    5
#define OLED_RESET 17

U8G2_SH1106_128X64_VCOMH0_1_4W_HW_SPI u8g2(U8G2_R0, /* cs=*/ 5, /* dc=*/ 16, /* reset=*/ 17);	

#define LCDWidth                        u8g2.getDisplayWidth()
#define ALIGN_CENTER(t)                 ((LCDWidth - (u8g2.getUTF8Width(t))) / 2)
#define ALIGN_RIGHT(t)                  (LCDWidth -  u8g2.getUTF8Width(t))
#define ALIGN_LEFT                      0

int mah;
int wh;

void u8g2_ascii_1() {
  u8g2.setFontMode(1);
  u8g2.setFont(u8g2_font_helvB14_tf);	
  u8g2.setCursor(0,14);
  u8g2.print(F("54.6 V"));
  u8g2.setCursor(80,14);
  u8g2.print(F("RUN"));
  u8g2.setCursor( ALIGN_RIGHT(String(mah).c_str())-55, 40 );
  u8g2.print(mah);
  u8g2.setCursor(80, 40);
  u8g2.print(F("mAh"));  
  u8g2.setCursor( ALIGN_RIGHT(String(wh).c_str())-55, 63 );
  u8g2.print(wh);
  u8g2.setCursor(80, 63);
  u8g2.print(F("Wh"));  
}

void setup(void) {
  Serial.begin(9600);
  delay(2000);
  SPI.begin(OLED_CLK,-1,OLED_MOSI,OLED_CS);
  u8g2.begin();
  u8g2.setContrast(250);
}


void loop(void) {
wh = random(20, 180);
mah = random(10200, 13800);
  // picture loop  
  u8g2.firstPage();  
  do {
    u8g2_ascii_1();
  } while( u8g2.nextPage() );
  

  delay(1000);
}