build.gradle

group 'com.github.jchipmunk.strelastik'
version '0.0.1-SNAPSHOT'

buildscript {
    ext.kotlin_version = '1.3.21'
    ext.jackson_version = '2.9.8'
    ext.spec_version = '1.1.5'

    repositories {
        jcenter()
        mavenCentral()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

apply plugin: 'kotlin'
apply plugin: 'application'
apply plugin: 'idea'

idea {
    module {
        downloadJavadoc = true
        downloadSources = true
    }
}

mainClassName = 'com.github.jchipmunk.strelastik.StrelastikKt'

sourceCompatibility = 1.8
compileKotlin {
    kotlinOptions.jvmTarget = '1.8'
}
compileTestKotlin {
    kotlinOptions.jvmTarget = '1.8'
}

test {
    useJUnitPlatform() {
        includeEngines 'spek'
    }
}

task copyLicense {
    outputs.file new File("$buildDir/LICENSE")
    doLast {
        copy {
            from "LICENSE"
            into "$buildDir"
        }
    }
}

applicationDistribution.from(copyLicense) {
    into ""
}

repositories {
    jcenter()
    mavenCentral()
    maven { url 'https://dl.bintray.com/jetbrains/spek' }
}

dependencies {
    compile "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlin_version"
    compile "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"
    compile "ch.qos.logback:logback-classic:1.2.3"
    compile "com.google.guava:guava:21.0"
    compile "com.beust:jcommander:1.72"
    compile "com.fasterxml.jackson.core:jackson-core:$jackson_version"
    compile "com.fasterxml.jackson.core:jackson-databind:$jackson_version"
    compile "com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:$jackson_version"
    compile "com.fasterxml.jackson.core:jackson-annotations:$jackson_version"
    compile "com.fasterxml.jackson.module:jackson-module-kotlin:$jackson_version"
    compile "com.github.spullara.mustache.java:compiler:0.9.6"
    compile "io.dropwizard.metrics:metrics-core:4.0.5"
    compile "io.searchbox:jest:5.3.4"
    compile("org.apache.zookeeper:zookeeper:3.4.14") {
        exclude group: "org.slf4j", module: "slf4j-log4j12"
    }
    compile("org.apache.curator:curator-framework:4.2.0") {
        exclude group: "org.apache.zookeeper", module: "zookeeper"
    }

    testCompile "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"
    testCompile "org.junit.jupiter:junit-jupiter-api:5.2.0"
    testCompile "org.jetbrains.spek:spek-api:$spec_version"
    testRuntime "org.jetbrains.spek:spek-junit-platform-engine:$spec_version"
}