build.gradle

println("Java: " + System.getProperty("java.version") + " JVM: " + System.getProperty("java.vm.version") + "(" + System.getProperty("java.vendor") + ") Arch: " + System.getProperty("os.arch"))
subprojects {
    apply plugin: "java"
    apply plugin: "idea"
    apply plugin: 'maven-publish'

    java.toolchain.languageVersion = JavaLanguageVersion.of(17)

    version = mod_version
    group = mod_group

    base {
        archivesName = "$mod_name-$minecraft_version-$project.name"
    }

    jar {
        manifest {
            attributes([
                    "Specification-Title"     : mod_id,
                    "Specification-Vendor"    : mod_authors,
                    "Specification-Version"   : "1",
                    "Implementation-Title"    : "$mod_id-$project.name",
                    "Implementation-Version"  : project.jar.archiveVersion,
                    "Implementation-Vendor"   : mod_authors,
                    "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
            ])
        }
    }

    repositories {
        mavenCentral()
        maven { url "https://www.cursemaven.com" }
        maven { url "file://${rootDir}/publishing" }
        maven { url = "https://api.modrinth.com/maven" }
        maven { url "https://maven.bai.lol" }
    }

    dependencies {
        testImplementation "org.junit.jupiter:junit-jupiter-api:5.8.2"
        testImplementation group: "org.hamcrest", name: "hamcrest", version: "2.2"
        testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:5.8.2"
    }

    test {
        useJUnitPlatform()
    }

    publishing {
        publications {
            mavenJava(MavenPublication) {
                artifact jar
            }
        }
        repositories {
            maven {
                url "file://${rootDir}/publishing"
            }
        }
    }

    tasks.withType(JavaCompile).configureEach {
        it.options.encoding = "UTF-8"
        it.options.release = 17
    }
}