CMakeLists.txt

cmake_minimum_required(VERSION 3.16)
cmake_policy(SET CMP0091 NEW)
project(AtomicParsley)

option(STATIC_LINK "build statically linked binary (not macOS) [default=OFF]" OFF)
option(MULTILIB_I386 "build 32-bit Intel binary via multilib (Linux only) [default=OFF]" OFF)
option(WITH_ZLIB "build with zlib [default=ON]" ON)
option(UNIVERSAL2_BINARY "build x86_64/arm64 universal2 binary (macOS only) [default=OFF]" OFF)
option(ARTWORK_RESIZE "automatically resize artwork (macOS only) [default=ON]" ON)
option(CREATOR_CODES "set creator/type codes on output files (macOS only) [default=ON]" ON)
option(DEBUG_OUTPUT "build binary with debug output [default=OFF]" OFF)
option(ADDRESS_SANITIZER "build binary with address sanitizer [default=OFF]" OFF)

string(COMPARE EQUAL ${CMAKE_SYSTEM_NAME} "Linux" LINUX)

if(STATIC_LINK AND NOT ADDRESS_SANITIZER AND NOT APPLE)
	set(STATIC 1)
else()
	set(STATIC 0)
endif()

if(NOT CMAKE_CONFIG_TYPE)
	if(ADDRESS_SANITIZER)
		set(CMAKE_CONFIG_TYPE Debug)
	else()
		set(CMAKE_CONFIG_TYPE Release)
	endif()
endif()

if(APPLE)
	if(NOT CMAKE_OSX_DEPLOYMENT_TARGET})
		set(CMAKE_OSX_DEPLOYMENT_TARGET 10.10)
	endif()
endif()

if(NOT PACKAGE_VERSION)
	find_program(git_exe git)
	if(git_exe)
		execute_process(
			COMMAND "${git_exe}" describe --tags --dirty
			WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
			RESULT_VARIABLE git_result
			OUTPUT_VARIABLE git_output
			ERROR_VARIABLE git_error
			OUTPUT_STRIP_TRAILING_WHITESPACE
		)
		if(git_result EQUAL 0)
			set(PACKAGE_VERSION ${git_output})
		else()
			message(FATAL_ERROR "Could not obtain version information with git\n${git_error}")
		endif()
	else()
		message(FATAL_ERROR "Could not locate git to obtain version information")
	endif()
endif()

add_executable(AtomicParsley)

list(APPEND ap_sources
	src/CDtoc.cpp
	src/arrays.cpp
	src/compress.cpp
	src/extracts.cpp
	src/iconv.cpp
	src/id3v2.cpp
	src/main.cpp
	src/metalist.cpp
	src/parsley.cpp
	src/sha1.cpp
	src/util.cpp
	src/uuid.cpp
)

target_compile_definitions(
	AtomicParsley
	PRIVATE
	-DPACKAGE_VERSION="${PACKAGE_VERSION}"
	-D_FILE_OFFSET_BITS=64
)

if(LINUX AND MULTILIB_I386)
	set(CMAKE_LIBRARY_ARCHITECTURE "i386-linux-gnu")
	target_compile_options(AtomicParsley PRIVATE "-m32")
	target_link_options(AtomicParsley PRIVATE "-m32")
endif()

if(STATIC)
	if(MSVC)
		set_property(TARGET AtomicParsley PROPERTY MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")
	else()
		target_link_options(AtomicParsley PRIVATE "-static")
	endif()
endif()

if(WITH_ZLIB)
	if(STATIC)
		if(MSVC)
			set(CMAKE_FIND_LIBRARY_SUFFIXES "static.lib")
		else()
			set(CMAKE_FIND_LIBRARY_SUFFIXES ".a")
		endif()
	endif()
	if(MSVC AND NOT ZLIB_ROOT)
		if(CMAKE_GENERATOR_PLATFORM STREQUAL "Win32")
			set(_ZLIB_x86 "(x86)")
			set(ZLIB_ROOT "$ENV{ProgramFiles${_ZLIB_x86}}/zlib")
		endif()
	endif()
	find_package(ZLIB)
	if(NOT ZLIB_FOUND)
		if(MSVC)
			list(APPEND ZLIB_CMAKE_ARGS "-DCMAKE_INSTALL_PREFIX:PATH=${CMAKE_BINARY_DIR}/zlib")
			if(STATIC)
				list(APPEND ZLIB_CMAKE_ARGS "-DCMAKE_POLICY_DEFAULT_CMP0091:STRING=NEW" "-DCMAKE_MSVC_RUNTIME_LIBRARY:STRING=MultiThreaded$<$<CONFIG:Debug>:Debug>")
			endif()
			include(ExternalProject)
			ExternalProject_Add(
				zlib
				GIT_REPOSITORY https://github.com/madler/zlib.git
				GIT_TAG v1.2.13
				GIT_SHALLOW 1
				PREFIX zlib
				CMAKE_ARGS ${ZLIB_CMAKE_ARGS}
			)
			ExternalProject_Get_Property(zlib INSTALL_DIR)
			if(STATIC)
				set(ZLIB_LIBRARY "${INSTALL_DIR}/lib/zlibstatic.lib")
			else()
				set(ZLIB_LIBRARY "${INSTALL_DIR}/lib/zlib.lib")
			endif()
			set(ZLIB_INCLUDE_DIR "${INSTALL_DIR}/include")
			find_package(ZLIB)
			if(ZLIB_FOUND)
				add_dependencies(AtomicParsley zlib)
				if(NOT STATIC)
					set(ap_zlib_dll "zlib.dll")
					add_custom_command(
						TARGET AtomicParsley
						POST_BUILD
						VERBATIM
						COMMAND
							"${CMAKE_COMMAND}" -E copy
								"${INSTALL_DIR}/bin/zlib.dll"
								"$<TARGET_FILE_DIR:AtomicParsley>/${ap_zlib_dll}"
					)
				endif()
			endif()
		else()
			message(FATAL_ERROR "Could not locate zlib\nInstall zlib or use -DWITH_ZLIB=OFF")
		endif()
	endif()
	if(ZLIB_FOUND)
		target_compile_definitions(AtomicParsley PRIVATE -DHAVE_ZLIB_H)
		target_include_directories(AtomicParsley PRIVATE ${ZLIB_INCLUDE_DIRS})
		target_link_libraries(AtomicParsley PRIVATE	${ZLIB_LIBRARIES})
	endif()
endif()

if(APPLE)
	enable_language(OBJC)
	enable_language(OBJCXX)
	if(UNIVERSAL2_BINARY)
		set_target_properties(AtomicParsley PROPERTIES OSX_ARCHITECTURES "x86_64;arm64")
	endif()
	if(ARTWORK_RESIZE)
		list(APPEND ap_sources src/nsimage.mm)
		target_compile_definitions(AtomicParsley PRIVATE -DARTWORK_RESIZE)
		target_link_libraries(AtomicParsley PRIVATE "-framework Cocoa")
	endif()
	if(CREATOR_CODES)
		list(APPEND ap_sources src/nsfile.mm)
		target_compile_definitions(AtomicParsley PRIVATE -DCREATOR_CODES)
	endif()
	target_link_libraries(AtomicParsley PRIVATE "-framework Foundation" "-framework IOKit")
endif()

if(DEBUG_OUTPUT)
	target_compile_definitions(AtomicParsley PRIVATE -DDEBUG_V)
endif()

if (ADDRESS_SANITIZER)
	target_compile_options(AtomicParsley PRIVATE "-fno-omit-frame-pointer" "-fsanitize=address")
	target_link_options(AtomicParsley PRIVATE "-fno-omit-frame-pointer" "-fsanitize=address")
endif()

include(CheckIncludeFileCXX)
check_include_file_cxx(getopt.h HAVE_GETOPT_H)
if(NOT HAVE_GETOPT_H)
	list(APPEND ap_sources src/extras/getopt.c src/extras/getopt1.c)
	check_include_file_cxx(libintl.h HAVE_LIBINTL_H)
	if(HAVE_LIBINTL_H)
		target_compile_definitions(AtomicParsley PRIVATE -DHAVE_LIBINTL_H)
	endif()
	check_include_file_cxx(string.h HAVE_STRING_H)
	if(HAVE_STRING_H)
		target_compile_definitions(AtomicParsley PRIVATE -DHAVE_STRING_H)
	endif()
endif()

include(CheckSymbolExists)
check_symbol_exists(fseeko stdio.h HAVE_FSEEKO)
if(HAVE_FSEEKO)
	target_compile_definitions(AtomicParsley PRIVATE -DHAVE_FSEEKO)
endif()
check_symbol_exists(lroundf math.h HAVE_LROUNDF)
if(HAVE_SRANDDEV)
	target_compile_definitions(AtomicParsley PRIVATE -DHAVE_SRANDDEV)
endif()
check_symbol_exists(srrandev stdlib.h HAVE_SRANDDEV)
if(HAVE_LROUNDF)
	target_compile_definitions(AtomicParsley PRIVATE -DHAVE_LROUNDF)
endif()
check_symbol_exists(strsep string.h HAVE_STRSEP)
if(HAVE_STRSEP)
	target_compile_definitions(AtomicParsley PRIVATE -DHAVE_STRSEP)
endif()

target_sources(AtomicParsley PRIVATE ${ap_sources})

install(TARGETS AtomicParsley RUNTIME)

string(TOLOWER ${CMAKE_SYSTEM_NAME} ap_system)
if(APPLE)
	set(ap_system macos)
	get_target_property(ap_arch AtomicParsley OSX_ARCHITECTURES)
	list(LENGTH ap_arch ap_arch_len)
	if(ap_arch_len GREATER 1)
		set(ap_arch universal2)
	endif()
elseif(LINUX)
	if(MULTILIB_I386)
		set(ap_arch i386)
	else()
		set(ap_arch x86_64)
	endif()
else()
	if(MSVC AND "${CMAKE_GENERATOR_TOOLSET}" MATCHES "xp")
		set(ap_system winxp)
	elseif(MINGW)
		set(ap_system msys2)
	endif()
    if(CMAKE_SIZEOF_VOID_P EQUAL 4)
		set(ap_arch i386)
	else()
		set(ap_arch x86_64)
	endif()
endif()
if(STATIC)
	set(ap_link static)
else()
	set(ap_link shared)
endif()
set(ap_release_dir "${CMAKE_SOURCE_DIR}/release/${PACKAGE_VERSION}")
set(ap_release_zip "AtomicParsley-${PACKAGE_VERSION}-${ap_system}-${ap_arch}-${ap_link}.zip")
add_custom_target(
	release
	VERBATIM
	WORKING_DIRECTORY "$<TARGET_FILE_DIR:AtomicParsley>"
	COMMAND
		"${CMAKE_COMMAND}" -E copy
			"${CMAKE_SOURCE_DIR}/COPYING"
			"${CMAKE_SOURCE_DIR}/CREDITS"
			"."
	COMMAND
		"${CMAKE_COMMAND}" -E tar c
			${ap_release_zip}
			--format=zip
			"$<TARGET_FILE_NAME:AtomicParsley>"
			"COPYING"
			"CREDITS"
			${ap_zlib_dll}
	COMMAND
		"${CMAKE_COMMAND}" -E sha256sum ${ap_release_zip} > "${ap_release_zip}.sha256"
	COMMAND
		"${CMAKE_COMMAND}" -E make_directory "${ap_release_dir}"
	COMMAND
		"${CMAKE_COMMAND}" -E rename
			${ap_release_zip}
			"${ap_release_dir}/${ap_release_zip}"
	COMMAND
		"${CMAKE_COMMAND}" -E rename
			"${ap_release_zip}.sha256"
			"${ap_release_dir}/${ap_release_zip}.sha256"
	COMMAND
		"${CMAKE_COMMAND}" -E remove -f
			"COPYING"
			"CREDITS"
)
add_dependencies(release AtomicParsley)