main.tf

### VPC ###

data "aws_availability_zones" "available" {}

resource "aws_vpc" "main" {
  cidr_block = var.cidr_block

  enable_dns_hostnames = true

  tags = {
    Name = var.vpc_name
  }
}

## Private subnets

locals {
  num_private_subnets = length(var.private_subnet_cidrs)
}

resource "aws_subnet" "private" {
  count             = local.num_private_subnets
  vpc_id            = aws_vpc.main.id
  cidr_block        = var.private_subnet_cidrs[count.index]
  availability_zone = data.aws_availability_zones.available.names[count.index]

  tags = {
    Name = "${var.private_subnet_name_prefix}[${count.index}]"
  }
}

## Public subnets

locals {
  num_public_subnets = length(var.private_subnet_cidrs)
}

resource "aws_subnet" "public" {
  count             = local.num_public_subnets
  vpc_id            = aws_vpc.main.id
  cidr_block        = var.public_subnet_cidrs[count.index]
  availability_zone = data.aws_availability_zones.available.names[count.index]

  tags = {
    Name = "${var.public_subnet_name_prefix}[${count.index}]"
  }
}

resource "aws_internet_gateway" "main" {
  vpc_id = aws_vpc.main.id

  tags = {
    Name = var.internet_gateway_name
  }
}

resource "aws_route_table" "public" {
  vpc_id = aws_vpc.main.id

  route {
    cidr_block = "0.0.0.0/0"
    gateway_id = aws_internet_gateway.main.id
  }

  tags = {
    Name = var.public_route_table_name
  }
}

resource "aws_route_table_association" "public" {
  count          = local.num_public_subnets
  subnet_id      = aws_subnet.public[count.index].id
  route_table_id = aws_route_table.public.id
}