What is the maximum WIFI data rate on the Pico W using the Arduino Pico Development system?

[frohro]

Hi All,
I am attempting to transfer audio data across WIFI using UDP. I have code working that sends 1404 bytes of data in each packet (a tad less than the MTU). It works up to 16 kHz with ASCII data (about 2 Mbps). I should be able to get 48 kHz by using binary, but I'd really like 96 kHz. I looked at the CYW43439 data sheet and it will go to 200 Mbps, and I found this blog post that was getting 20 Mbps over TCP. What is the maximum data rate over WIFI you have been able to achieve with the Arduino Pico development tools? And if you have any suggestions to make my code faster, I would really appreciate them!
Thanks,
Rob
P.S. In case you are interested, here is my code for testing the data rate.

/*
 * This Pico W program will connect to the PCM1808 via I2S and read the data it RATE samples per second.
 * It then sends the dato over WIFI using UDP.  To receive it and plot the results, you can use the 
 * python scripts and this sequence in Linux:
 * $ rm sound_data.csv 
 * $ nc -u -l 12345 > sound_data.csv
 * ^C
 * $ python3 plot_sound_data.py
 * The ^C is to stop the nc process which is receiving the data and saving it to sound_data.csv.
 * You can see that every oonce in a while there will be what appears to be a zero in the data.
 * We will have to remove them.  We also have to remove about 90 samples every second at 96 kHz
 * sampling rate.  (Less at slower sampling rates, because the Pico does not have exactly the right
 * crystal frequency to get exactly the audio rate we need.  We could reduce the load on the network
 * by sending the data in a binary way.  It appears we are getting almost 20 Mbits/s through the WIFI!
 * 
 * Author: Rob Frohne, KL7NA, with help from Perplexity and Github Copilot and others.
 * 3/9/2024
 */
#include <Arduino.h>
#include <I2S.h>
#include <WiFi.h>
#include <WiFiUdp.h>

#ifndef STASSID
#define STASSID Frohne-2.4GHz
#endif

#define RATE 16000
#define MCLK_MULT 256  // 384 for 48 BCK per frame,  256 for 64 BCK per frame

I2S i2s(INPUT);

WiFiUDP udp;  
void setup() {
  Serial.begin();

  i2s.setDATA(2);  // These are the pins for the data on the SDR-TRX
  i2s.setBCLK(0);
  i2s.setMCLK(3);
  // Note: LRCK pin is BCK pin plus 1 (1 in this case).
  i2s.setBitsPerSample(24);
  i2s.setFrequency(RATE);
  i2s.setMCLKmult(MCLK_MULT);
  i2s.setSysClk(RATE);
  i2s.setBuffers(32, 0, 0);

  WiFi.begin("Frohne-2.4GHz");

   while (WiFi.status() != WL_CONNECTED) {
    delay(10000);
    Serial.println ("Trying to connect to WiFi...");
  }
  Serial.println("WiFi connected");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  udp.begin(12345);
  i2s.begin();
}

const size_t BUFFER_SIZE = 1404;  // Assuming the MTU is 1500 bytes...
char buffer[BUFFER_SIZE];
const char* udpAddress = "192.168.1.101";  // Put your laptop IP here.
const unsigned int udpPort = 12345;


void loop() {
  static int32_t r, l;
  size_t bufferIndex = 0;

  // Fill the buffer with 108 lines of "%d\r\n"
  while (bufferIndex < BUFFER_SIZE - 26) { // 13 is the max size of "%d\r\n" with 10 digits
    i2s.read32(&l, &r); // Read the next l and r values
    l = l<<9;
    r = r<<9;

    // These next lines create the buffer of slightly less that the MTU (1500 bytes)
    int n = snprintf(buffer + bufferIndex, BUFFER_SIZE - bufferIndex, "%d,%d\r\n", l, r);
    if (n > 0) {
      bufferIndex += n;
    } else {
      Serial.println("Problem with buffer!");
      break;
    }
  }

  // Send the buffer via UDP
  udp.beginPacket(udpAddress, udpPort);
  udp.write((const uint8_t*)buffer, bufferIndex);
  udp.endPacket();

  // Clear the buffer for the next round
  memset(buffer, 0, BUFFER_SIZE);
}

[frohro]

It looks like I should be able to get more bandwidth. Here is a youtube video of someone using iperf3 to get 7.5 Mbps on the PicoW. So I guess now, my question is how do I optimize my code above? If I change the RATE to 48000, I get gaps in the sinewave I am connecting to the ADC.

[frohro]

I deleted all the I2S stuff above to find the maximum throughput I can got (using this library) and I get 990 kB/s which is 7.9 Mb/s using the System Monitor of Ubuntu. If anyone sees a good way to speed this up, I would like to hear about it. :-)

Here is my code:

/* Basic_Testing_UDP_Data_Stream for speed.  I get 990 kB/s with this code.
 * I am using the Ubuntu System Monitor to measure this.
 * Author: Rob Frohne, KL7NA, with help from Perplexity and Github Copilot.
 * 4/9/2024
 */
#include <Arduino.h>
#include <WiFi.h>
#include <WiFiUdp.h>
#include <si5351.h>

#ifndef STASSID
#define STASSID Frohne - 2.4GHz
#endif

WiFiUDP udp;
void setup()
{

    WiFi.begin("Frohne-2.4GHz");
    while (WiFi.status() != WL_CONNECTED)
    {
        delay(10000);
    }

    udp.begin(12345);
}

const size_t BUFFER_SIZE = 1470; // Assuming the MTU is 1500 bytes...
char buffer[BUFFER_SIZE];
const char *udpAddress = "192.168.1.101"; // Put your laptop IP here.
const unsigned int udpPort = 12345;

void loop()
{
    // Send the buffer via UDP
    udp.beginPacket(udpAddress, udpPort);
    udp.write((const uint8_t *)buffer, BUFFER_SIZE);
    udp.endPacket();
}

[frohro]

I found a reference and code using the Pico SDK that gets 2 MB/s which is twice as fast as my code above. Is there a way to use code from the Pico SDK with Arduino Pico?

[earlephilhower]

You should be able to call native LWIP calls, but you'd just be duplicating what's in the classes. I would also check the lwipipts.h file to see if there are different buffer and timeout settings.