build.gradle

plugins {
    id 'fabric-loom' version '0.12-SNAPSHOT'
    id 'maven-publish'
    id "com.modrinth.minotaur" version "2.7.4"
    id "net.darkhax.curseforgegradle" version "1.0.11"
}

version = project.mod_version
group = project.maven_group

repositories {
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"
}

processResources {
    inputs.property "version", project.version
    filteringCharset "UTF-8"

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

def targetJavaVersion = 16
tasks.withType(JavaCompile).configureEach {
    // ensure that the encoding is set to UTF-8, no matter what the system default is
    // this fixes some edge cases with special characters not displaying correctly
    // see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
    // If Javadoc is generated, this must be specified in that task too.
    it.options.encoding = "UTF-8"
    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        it.options.release = targetJavaVersion
    }
}

java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
    archivesBaseName = project.archives_base_name
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    // If you remove this line, sources will not be generated.
    withSourcesJar()
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.archivesBaseName}" }
    }
}


// Mod publishing

import net.darkhax.curseforgegradle.TaskPublishCurseForge

def versionDisplayName = project.mod_name + ' - ' + project.version
def supportedMinecraftVersions = project.mod_supported_minecraft_versions.split(',').toList()
def changelogText = new File('./CHANGELOG.md').text

modrinth
{
    group 'upload'
    token = project.modrinth_token // saved in user home
    projectId = project.modrinth_mod_id
    versionName = versionDisplayName
    versionNumber = project.version
    versionType = project.mod_version_type

    gameVersions = supportedMinecraftVersions
    loaders = ["fabric", "quilt"]
    changelog = changelogText
    dependencies
    {
        required.project "fabric-api"
    }

    uploadFile = remapJar
}


task curseforge(type: TaskPublishCurseForge)
{
    group 'upload'
    apiToken = project.curseforge_token // saved in user home

    disableVersionDetection()
    def mainFile = upload(curseforge_mod_id, remapJar)
    mainFile.changelog = changelogText
    mainFile.changelogType = 'markdown'
    mainFile.releaseType = project.mod_version_type
    mainFile.displayName = versionDisplayName
    mainFile.addModLoader('Fabric')
    mainFile.addModLoader('Quilt')
    for (ver in supportedMinecraftVersions)
    {
        mainFile.addGameVersion(ver)
    }
    mainFile.addRelation('fabric-api', 'requiredDependency')
}