МенеджерВопросов

[SeiOkami]

#Область МенеджерВопросов

Функция МенеджерВопросов(ОписаниеОповещения) Экспорт
	
	МенеджерВопросов = Новый Структура;
	МенеджерВопросов.Вставить("Вопросы", Новый Массив);
	МенеджерВопросов.Вставить("ТекущийВопрос", Неопределено);
	МенеджерВопросов.Вставить("ОписаниеОповещенияОЗавершении", ОписаниеОповещения);
	
	Возврат МенеджерВопросов;
	
КонецФункции

Функция МенеджерВопросов_ДобавитьВопрос(МенеджерВопросов, 
	ТекстВопроса, Кнопки, Имя = "", ДополнительныеПараметры = Неопределено) Экспорт
	
	ОписаниеВопроса = Новый Структура();
	ОписаниеВопроса.Вставить("Имя", Имя);
	ОписаниеВопроса.Вставить("Ответ", Неопределено);
	ОписаниеВопроса.Вставить("Кнопки", Кнопки);
	ОписаниеВопроса.Вставить("Таймаут", 0);
	ОписаниеВопроса.Вставить("Заголовок", "");
	ОписаниеВопроса.Вставить("ТекстВопроса", ТекстВопроса);
	ОписаниеВопроса.Вставить("КнопкаТаймаута", Неопределено);
	ОписаниеВопроса.Вставить("КнопкаПоУмолчанию", Неопределено);
	ОписаниеВопроса.Вставить("ДополнительныеПараметры", ДополнительныеПараметры);
	
	МенеджерВопросов.Вопросы.Добавить(ОписаниеВопроса);
	
	Возврат ОписаниеВопроса;
	
КонецФункции

Процедура МенеджерВопросов_ПоказатьВопросы(МенеджерВопросов) Экспорт
	
	МенеджерВопросов_ПоказатьСледующийВопрос(МенеджерВопросов);
	
КонецПроцедуры

Процедура МенеджерВопросов_ПоказатьВопрос(МенеджерВопросов, Знач ОписаниеВопроса)
	
	Если ТипЗнч(ОписаниеВопроса) = Тип("Число") Тогда
		ОписаниеВопроса = МенеджерВопросов.Вопросы.Получить(ОписаниеВопроса);
	КонецЕсли;
	
	МенеджерВопросов.ТекущийВопрос = ОписаниеВопроса;
	
	ДополнительныеПараметры = Новый Структура;
	ДополнительныеПараметры.Вставить("МенеджерВопросов", МенеджерВопросов);
	
	ОписаниеОповещения = Новый ОписаниеОповещения("МенеджерВопросов_ОбработатьОтвет", ЭтотОбъект, ДополнительныеПараметры);
	
	ПоказатьВопрос(ОписаниеОповещения, ОписаниеВопроса.ТекстВопроса, ОписаниеВопроса.Кнопки, 
	ОписаниеВопроса.Таймаут, ОписаниеВопроса.КнопкаПоУмолчанию, ОписаниеВопроса.Заголовок, ОписаниеВопроса.КнопкаТаймаута);
	
КонецПроцедуры

Процедура МенеджерВопросов_ПоказатьСледующийВопрос(МенеджерВопросов)
	
	ТекущийВопрос = МенеджерВопросов.ТекущийВопрос;
	Если ТекущийВопрос = Неопределено Тогда
		ТекущийВопрос = 0;
	Иначе
		ТекущийВопрос = МенеджерВопросов.Вопросы.Найти(ТекущийВопрос);
		ТекущийВопрос = ТекущийВопрос + 1;
	КонецЕсли;
	
	Если ТекущийВопрос > МенеджерВопросов.Вопросы.Количество() - 1 Тогда
		МенеджерВопросов_Завершить(МенеджерВопросов);
	Иначе
		МенеджерВопросов_ПоказатьВопрос(МенеджерВопросов, ТекущийВопрос);
	КонецЕсли;
	
КонецПроцедуры

Процедура МенеджерВопросов_Завершить(МенеджерВопросов)
	
	ВыполнитьОбработкуОповещения(МенеджерВопросов.ОписаниеОповещенияОЗавершении, МенеджерВопросов);
	
КонецПроцедуры

Процедура МенеджерВопросов_ОбработатьОтвет(ОтветПользователя, ДополнительныеПараметры) Экспорт
	
	МенеджерВопросов = ДополнительныеПараметры.МенеджерВопросов;
	МенеджерВопросов.ТекущийВопрос.Ответ = ОтветПользователя;
	МенеджерВопросов_ПоказатьСледующийВопрос(МенеджерВопросов);
	
КонецПроцедуры

#КонецОбласти