How to use variables in options passed with fx:properties ? #215

enridaga · 2021-09-01T08:19:31Z

enridaga
Sep 1, 2021
Maintainer

FX properties are removed from the query pattern before evaluation.

For example, the following query does not work:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX fx:  <http://sparql.xyz/facade-x/ns/>
PREFIX xyz: <http://sparql.xyz/facade-x/data/>
PREFIX mei: <http://www.music-encoding.org/ns/mei#>
PREFIX xml: <http://www.w3.org/XML/1998/namespace#>

SELECT ?location ?lyrics
WHERE {
	VALUES (?location) { ("datasets/genius/iso_beatles_lyrics/lyrics_The Beatles_A Day In The Life.json") }
	SERVICE <x-sparql-anything:> {
		fx:properties fx:location ?location ;
			fx:media-type "application/json"
		.
	#	?A ?B ?C
		[] xyz:lyrics ?lyrics
	}
}

While this seems to work:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX fx:  <http://sparql.xyz/facade-x/ns/>
PREFIX xyz: <http://sparql.xyz/facade-x/data/>
PREFIX mei: <http://www.music-encoding.org/ns/mei#>
PREFIX xml: <http://www.w3.org/XML/1998/namespace#>

SELECT ?location ?lyrics
WHERE {
	SERVICE <x-sparql-anything:> {
		fx:properties fx:location "datasets/genius/iso_beatles_lyrics/lyrics_The Beatles_A Day In The Life.json" ;
			fx:media-type "application/json"
		.
		[] xyz:lyrics ?lyrics
	}
}

and this is a temporary solution:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX fx:  <http://sparql.xyz/facade-x/ns/>
PREFIX xyz: <http://sparql.xyz/facade-x/data/>
PREFIX mei: <http://www.music-encoding.org/ns/mei#>
PREFIX xml: <http://www.w3.org/XML/1998/namespace#>

SELECT ?location ?lyrics
WHERE {
	VALUES (?location) { ("datasets/genius/iso_beatles_lyrics/lyrics_The Beatles_A Day In The Life.json") }
	BIND (IRI(CONCAT("x-sparql-anything:","location=", ?location )) AS ?fx) .
	SERVICE ?fx {
		fx:properties
			fx:media-type "application/json"
		.
	#	?A ?B ?C
		[] xyz:lyrics ?lyrics
	}
}

However, setting properties dynamically is very useful.

justin2004 · 2021-09-01T11:34:28Z

justin2004
Sep 1, 2021

However, setting properties dynamically is very useful.

yes!

i also encountered the fx:properties fx:location ?location problem and i tried to fix the case where you use bind to set ?location.

basically i wanted to get "fred" into ?o in the (bgp):

(join
  (extend ((?o "fred"))
    (table unit))
  (bgp (triple ?s ?p ?o)))

i was hoping there was a swift solution so i tried:
org.apache.jena.sparql.algebra.optimize.TransformSimplify
org.apache.jena.sparql.algebra.optimize.TransformEliminateAssignments/eliminate
org.apache.jena.sparql.algebra.optimize.TransformRemoveAssignment
org.apache.jena.sparql.algebra.optimize.Optimize/apply

but those methods didn't have the right behavior.
but i think the solution might involve walking the tree and replacing occurrences of ?o with "fred"?
or is there a better approach?

0 replies

enridaga · 2021-09-01T14:32:43Z

enridaga
Sep 1, 2021
Maintainer Author

One way of doing it is to postpone the execution of the inner SERVICE clause until all variables mentioned in fx:properties statements are evaluated. One implication is that the related BGP cannot be removed from the SERVICE clause until then, and this may create other problems (e.g. with caching).

0 replies

luigi-asprino · 2021-09-13T14:10:28Z

luigi-asprino
Sep 13, 2021
Maintainer

That's exactly the behaviour I tried to implement.
If a variable is detected as object of a triple having fx:properties as subject (e.g. fx:properties fx:location ?loc) an UnboundVariableException is raised (cf. here)

A fake pattern is then created (e.g. ?s ?p ?loc) and executed against the current context (cf. here)
The result of this executions feeds the execution of the original BGP (therefore the ?loc variable is bound).

Note that there already exists an integration test that assesses this feature

Said that, if you report the issue there is maybe something wrong going on here. Let's investigate

0 replies

luigi-asprino · 2021-09-14T07:09:17Z

luigi-asprino
Sep 14, 2021
Maintainer

4ce6d3b should fix this issue (at least partially)
The rationale of the commit is: if a variable (e.g. ?location) is detected in the property-BGP and the variable is assigned through a table (i.e. VALUES), then the variable is evaluated before processing the SERVICE clause.
However, this works only if the the table is inside the SERVICE clause


PREFIX  xyz:  <http://sparql.xyz/facade-x/data/>
PREFIX  fx:   <http://sparql.xyz/facade-x/ns/>
PREFIX  rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT  *
WHERE
  { SERVICE <x-sparql-anything:csv.headers=true>
      { fx:properties
                  fx:location         ?location ;
                  fx:csv.null-string  "" .
        ?s        rdf:_1              ?o .
        ?o        xyz:A               ?r
        VALUES ?location { "file:/Users/lgu/workspace/spice/sparql.anything/sparql.anything.it/target/test-classes/test1.csv" }
      }
  }

but not for


PREFIX  xyz:  <http://sparql.xyz/facade-x/data/>
PREFIX  fx:   <http://sparql.xyz/facade-x/ns/>
PREFIX  rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT  *
WHERE
  { VALUES ?location { "file:/Users/lgu/workspace/spice/sparql.anything/sparql.anything.it/target/test-classes/test1.csv" }
    SERVICE <x-sparql-anything:csv.headers=true>
      { fx:properties
                  fx:location         ?location ;
                  fx:csv.null-string  "" .
        ?s        rdf:_1              ?o .
        ?o        xyz:A               ?r
      }
  }

This is due to the fact that the FacadeXOpExecutor looks for tables only once the processing of the SERVICE clause has started and only for sub-operators of the SERVICE clause. Are we ok with this behaviour? I mean, I think that whatever is outside the SERVICE should be processed as SPARQL prescribes (the result of the table is joined with the result of the SERVICE once the service is processed). The evaluation of the SERVICE and its inner operators depends on the behaviour we want to implement in sparql anything.

0 replies

enridaga · 2021-09-14T10:04:47Z

enridaga
Sep 14, 2021
Maintainer Author

I mean, I think that whatever is outside the SERVICE should be processed as SPARQL prescribes (the result of the table is joined with the result of the SERVICE once the service is processed).

Thank you for looking into this, it makes a lot of sense. My original use case was using the VALUES clause to get the location from parameters passed through the CLI feature -i,--input <input> . I will test it by moving the values clause inside the SERVICE operator.

0 replies

enridaga · 2021-09-14T10:19:16Z

enridaga
Sep 14, 2021
Maintainer Author

Indeed, the following query is working nicely:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX fx:  <http://sparql.xyz/facade-x/ns/>
PREFIX xyz: <http://sparql.xyz/facade-x/data/>
PREFIX mei: <http://www.music-encoding.org/ns/mei#>
PREFIX xml: <http://www.w3.org/XML/1998/namespace#>

SELECT ?location ?lyrics
WHERE {
	SERVICE <x-sparql-anything:> {
		fx:properties fx:location ?location ;
			fx:media-type "application/json"
		.
		[] xyz:lyrics ?lyrics
		VALUES (?location) { ( ?_location ) }
	}
}

Executed as

fx -q service-variables.sparql -v location="https://raw.githubusercontent.com/polifonia-project/sonar2021_demo/datasets/datasets/genius/iso_beatles_lyrics/lyrics_The%20Beatles_A%20Day%20In%20The%20Life.json"

0 replies

justin2004 · 2021-09-14T12:27:06Z

justin2004
Sep 14, 2021

@luigi-asprino

this works:

curl --silent 'http://localhost:3000/sparql.anything' \
--header "Accept: text/csv" \
--data-urlencode 'query=
PREFIX fx: <http://sparql.xyz/facade-x/ns/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
prefix xhtml: <http://www.w3.org/1999/xhtml#>
prefix what: <https://html.spec.whatwg.org/#>
SELECT * 
where {
fx:properties fx:location "/app/some.csv" .
?s ?p ?o .
}'

but this does not:

curl --silent 'http://localhost:3000/sparql.anything' \
--header "Accept: text/csv" \
--data-urlencode 'query=
PREFIX fx: <http://sparql.xyz/facade-x/ns/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
prefix xhtml: <http://www.w3.org/1999/xhtml#>
prefix what: <https://html.spec.whatwg.org/#>
SELECT *
where {
values ?loc {"/app/some.csv"}
fx:properties fx:location ?loc .
?s ?p ?o .
}'

so right now it looks like the OpService is necessary for fx:properties variables.
that might cause confusion since OpService isn't required for lots of other queries.

also bind() becomes OpExtend which seems to be a little different than OpTable as this does not work:

curl --silent 'http://localhost:3000/sparql.anything' \
--header "Accept: text/csv" \
--data-urlencode 'query=
PREFIX fx: <http://sparql.xyz/facade-x/ns/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
prefix xhtml: <http://www.w3.org/1999/xhtml#>
prefix what: <https://html.spec.whatwg.org/#>
SELECT *
where {
service <x-sparql-anything:>{
  bind("/app/some.csv" as ?loc)
  fx:properties fx:location ?loc .
  ?s ?p ?o .
}
}'

0 replies

luigi-asprino · 2021-09-14T15:41:33Z

luigi-asprino
Sep 14, 2021
Maintainer

This commit a2ce6a7 should address the assignment via BIND operator.

0 replies

justin2004 · 2021-09-16T02:26:29Z

justin2004
Sep 16, 2021

bind also works for me now.

but the OpService is still necessary. this is minor i think but it might cause confusion for some users.
that is, this does not work when you invoke the sparql.anything fuseki endpoint:

PREFIX fx: <http://sparql.xyz/facade-x/ns/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
prefix xhtml: <http://www.w3.org/1999/xhtml#>
prefix what: <https://html.spec.whatwg.org/#>
SELECT *
where {
  bind("/app/some.csv" as ?loc) .
  fx:properties fx:location ?loc .
  ?s ?p ?o .
}

but it would be nice if postponing the execution of a service clause would, in general, allow things like:

curl --silent 'http://localhost:3000/sparql.anything' \
--header "Accept: text/csv" \
--data-urlencode 'query=
PREFIX fx: <http://sparql.xyz/facade-x/ns/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX xyz: <http://sparql.xyz/facade-x/data/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
prefix xhtml: <http://www.w3.org/1999/xhtml#>
prefix what: <https://html.spec.whatwg.org/#>
SELECT *
where {
  service <x-sparql-anything:csv.headers=true>{
  bind("/app/files.csv" as ?loc) .
  fx:properties fx:location ?loc .
  ?s xyz:file ?file .
  }
  service <x-sparql-anything:>{
  fx:properties fx:location ?file .
  ?s ?p ?o .
  }
}'

but that does not work right now.

0 replies

luigi-asprino · 2021-09-16T04:54:08Z

luigi-asprino
Sep 16, 2021
Maintainer

That's true. However you can maybe have the same behaviour by nesting the two service clause.

0 replies

Provide feedback

Saved searches

Use saved searches to filter your results more quickly

How to use variables in options passed with fx:properties ? #215

{{title}}

Replies: 10 comments

{{title}}

{{editor}}'s edit

{{editor}}'s edit

{{title}}

{{title}}

{{title}}

{{title}}

{{editor}}'s edit

{{editor}}'s edit

{{title}}

{{title}}

{{title}}

{{title}}

{{title}}

Select a reply

How to use variables in options passed with fx:properties ? #215

enridaga Sep 1, 2021 Maintainer

Replies: 10 comments

justin2004 Sep 1, 2021

enridaga Sep 1, 2021 Maintainer Author

luigi-asprino Sep 13, 2021 Maintainer

luigi-asprino Sep 14, 2021 Maintainer

enridaga Sep 14, 2021 Maintainer Author

enridaga Sep 14, 2021 Maintainer Author

justin2004 Sep 14, 2021

luigi-asprino Sep 14, 2021 Maintainer

justin2004 Sep 16, 2021

luigi-asprino Sep 16, 2021 Maintainer

enridaga
Sep 1, 2021
Maintainer

justin2004
Sep 1, 2021

enridaga
Sep 1, 2021
Maintainer Author

luigi-asprino
Sep 13, 2021
Maintainer

luigi-asprino
Sep 14, 2021
Maintainer

enridaga
Sep 14, 2021
Maintainer Author

enridaga
Sep 14, 2021
Maintainer Author

justin2004
Sep 14, 2021

luigi-asprino
Sep 14, 2021
Maintainer

justin2004
Sep 16, 2021

luigi-asprino
Sep 16, 2021
Maintainer