noyesbar.src

# noyesbar.src

# Sep 28 1995 - Digital Man

# $Id: noyesbar.src,v 1.11 2020/04/06 02:57:19 rswindell Exp $

# @format.tab-size 8, @format.use-tabs true

!include sbbsdefs.inc # _question

str tmp

copy tmp str
setstr "N"
compare_strn 2 _question "\r\n"
if_true
	crlf
	shift_str _question 2
	end_if
compare_strn 2 _question "\1?"
if_true
	print "\1?"
	shift_str _question 2
	end_if
print "\x01n\x01b\x01h[\x01c@CHECKMARK@\x01b] \x01y@QUESTION->@? "
:top
compare_str "N"
if_equal
	print "\x01h\x014\x01w\x01e[No]\x01n\x01b\x01h Yes "
else
	print "\x01n\x01b\x01h No \x014\x01w\x01e[Yes]"
	end_if
int aborted
copy aborted _sys_status
and aborted SS_ABORT
compare aborted SS_ABORT
if_not_equal
    getkey
    print "\b\b\b\b\b\b\b\b\b\1n\1h\1>"
    int aborted
    copy aborted _sys_status
    and aborted SS_ABORT
    compare aborted SS_ABORT
    if_equal
        return
        end_if
    end_if
if_equal
    return
    end_if
compare_key ^M
if_true
	ungetstr
	copy str tmp
	return
	end_if

compare_keys "YN"
if_true
	ungetkey
	copy str tmp
	return
	end_if

compare_key ^@
if_true
	copy str tmp
	return
	end_if

# Toggle
compare_str "Y"
if_true
	setstr "N"
else
	setstr "Y"
	end_if
goto top