-
Notifications
You must be signed in to change notification settings - Fork 3
/
Copy pathU_gnugettext.pas
4317 lines (3952 loc) · 145 KB
/
U_gnugettext.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
{*------------------------------------------------------------------------------
GNU gettext translation system for Delphi, Kylix, C++ Builder and others.
All parts of the translation system are kept in this unit.
@author Lars B. Dybdahl and others
@version $LastChangedRevision: 220 $
@see http://dybdahl.dk/dxgettext/
-------------------------------------------------------------------------------}
unit U_GnuGetText;
(**************************************************************)
(* *)
(* (C) Copyright by Lars B. Dybdahl and others *)
(* E-mail: [email protected], phone +45 70201241 *)
(* *)
(* Contributors: Peter Thornqvist, Troy Wolbrink, *)
(* Frank Andreas de Groot, Igor Siticov, *)
(* Jacques Garcia Vazquez, Igor Gitman, *)
(* Arvid Winkelsdorf, *)
(* Thomas Mueller (dummzeuch) *)
(* Olivier Sannier (obones) *)
(* *)
(* See http://dybdahl.dk/dxgettext/ for more information *)
(* *)
(**************************************************************)
// Information about this file:
// $LastChangedDate: 2010-08-25 15:40:17 +0200 (on, 25 aug 2010) $
// $LastChangedRevision: 220 $
// $HeadURL: http://svn.berlios.de/svnroot/repos/dxgettext/trunk/dxgettext/sample/gnugettext.pas $
// Redistribution and use in source and binary forms, with or without
// modification, are permitted provided that the following conditions are met:
//
// The names of any contributor may not be used to endorse or promote
// products derived from this software without specific prior written permission.
//
// THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
// AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
// IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
// ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
// LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
// DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
// SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
// CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
// OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
// OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
interface
// If the conditional define DXGETTEXTDEBUG is defined, debugging log is activated.
// Use DefaultInstance.DebugLogToFile() to write the log to a file.
{.$define DXGETTEXTDEBUG}
// If the conditional define dx_ChangeProxyClassname is defined, THookedObjects.Proxify adds '!dx'
// to the class name. Default: off
{.$define dx_ChangeProxyClassname}
// ### LO - Workaround aka hack for programs compiled with German Delphi
//
// If the current OS Language is not German, immediately add a Delphi RTL domain
// to the resource domains and bind the text domain to a fixed German->English
// translation.
// Using a fixed German->English translation because the OS
// Language may not be one of the installed translations.
// Otherwise the German RTL resourcestrings will not be translated.
// This results in German menu shortcuts 'Strg+', 'Umsch+' instead of
// 'Ctrl+', 'Shift+' and so on.
//
// Since there is no way to automatically determine whether the compiling version
// is German, you must enable the following conditional define to enable it.
// Be warned: This has not been thoroughly tested.
// Default is turned off.
{.$define dx_German_Delphi_fix}
// if the conditional define dx_SupportsResources is defined the .mo files
// can also be added to the executable as Windows resources
// Be warned: This has not been thoroughly tested.
// Default is turned off.
{.$define dx_SupportsResources}
{$ifdef VER140}
// Delphi 6
{$DEFINE dx_Hinstance_is_Integer}
{$DEFINE dx_NativeInt_is_Integer}
{$DEFINE dx_NativeUInt_is_Cardinal}
{$endif}
{$ifdef VER150}
// Delphi 7
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_Hinstance_is_Integer}
{$DEFINE dx_NativeInt_is_Integer}
{$DEFINE dx_NativeUInt_is_Cardinal}
{$endif}
{$ifdef VER160}
// Delphi 8
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_Hinstance_is_Integer}
{$DEFINE dx_NativeInt_is_Integer}
{$DEFINE dx_NativeUInt_is_Cardinal}
{$endif}
{$ifdef VER170}
// Delphi 2005
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_Hinstance_is_Integer}
{$DEFINE dx_NativeInt_is_Integer}
{$DEFINE dx_NativeUInt_is_Cardinal}
{$endif}
{$ifdef VER180}
{$ifndef VER185}
// Delphi 2006
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_Hinstance_is_Integer}
{$DEFINE dx_NativeInt_is_Integer}
{$DEFINE dx_NativeUInt_is_Cardinal}
{$DEFINE dx_has_Inline}
{$endif}
{$endif}
{$ifdef VER185}
// Delphi 2007
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_Hinstance_is_Integer}
{$DEFINE dx_NativeInt_is_Integer}
{$DEFINE dx_NativeUInt_is_Cardinal}
{$DEFINE dx_has_Inline}
{$endif}
// there was no VER190 ??
{$ifdef VER200}
// Delphi 2009, first version with Unicode
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_Hinstance_is_Integer}
{$DEFINE dx_NativeInt_is_Integer}
{$DEFINE dx_NativeUInt_is_Cardinal}
{$DEFINE dx_has_Inline}
{$DEFINE dx_StringList_has_OwnsObjects}
{$DEFINE dx_has_LpVoid}
{$endif}
{$ifdef VER210}
// Delphi 2010
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_Hinstance_is_Integer}
{$DEFINE dx_NativeInt_is_Integer}
{$DEFINE dx_NativeUInt_is_Cardinal}
{$DEFINE dx_has_Inline}
{$DEFINE dx_StringList_has_OwnsObjects}
{$DEFINE dx_has_LpVoid}
{$endif}
{$ifdef VER220}
// Delphi 2011/XE
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_Hinstance_is_Integer}
{$DEFINE dx_NativeInt_is_Integer}
{$DEFINE dx_NativeUInt_is_Cardinal}
{$DEFINE dx_has_Inline}
{$DEFINE dx_has_LpVoid}
{$DEFINE dx_StringList_has_OwnsObjects}
{$endif}
{$ifdef VER230}
// Delphi 2012/XE2
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_StringList_has_OwnsObjects}
{$DEFINE dx_has_Inline}
{$DEFINE dx_has_LpVoid}
{$DEFINE dx_has_VclThemes}
{$endif}
{$ifdef VER240}
// Delphi 2013/XE3
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_StringList_has_OwnsObjects}
{$DEFINE dx_GetStrProp_reads_unicode}
{$DEFINE dx_has_Inline}
{$DEFINE dx_has_LpVoid}
{$DEFINE dx_has_VclThemes}
{$endif}
{$ifdef VER250}
// Delphi XE4
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_StringList_has_OwnsObjects}
{$DEFINE dx_GetStrProp_reads_unicode}
{$DEFINE dx_has_Inline}
{$DEFINE dx_has_LpVoid}
{$DEFINE dx_has_VclThemes}
{$DEFINE dx_midstr_in_AnsiStrings}
{$endif}
{$ifdef VER260}
// Delphi XE5
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_StringList_has_OwnsObjects}
{$DEFINE dx_GetStrProp_reads_unicode}
{$DEFINE dx_has_Inline}
{$DEFINE dx_has_LpVoid}
{$DEFINE dx_has_VclThemes}
{$DEFINE dx_midstr_in_AnsiStrings}
{$endif}
{$ifdef VER270}
// Delphi XE6
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_StringList_has_OwnsObjects}
{$DEFINE dx_GetStrProp_reads_unicode}
{$DEFINE dx_has_Inline}
{$DEFINE dx_has_LpVoid}
{$DEFINE dx_has_VclThemes}
{$DEFINE dx_midstr_in_AnsiStrings}
{$endif}
{$ifdef VER280}
// Delphi XE7
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_StringList_has_OwnsObjects}
{$DEFINE dx_GetStrProp_reads_unicode}
{$DEFINE dx_has_Inline}
{$DEFINE dx_has_LpVoid}
{$DEFINE dx_has_VclThemes}
{$DEFINE dx_midstr_in_AnsiStrings}
{$endif}
{$ifdef VER290}
// Delphi XE8
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_StringList_has_OwnsObjects}
{$DEFINE dx_GetStrProp_reads_unicode}
{$DEFINE dx_has_Inline}
{$DEFINE dx_has_LpVoid}
{$DEFINE dx_has_VclThemes}
{$DEFINE dx_midstr_in_AnsiStrings}
{$endif}
{$ifdef VER300}
// Delphi 10 Seattle
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_StringList_has_OwnsObjects}
{$DEFINE dx_GetStrProp_reads_unicode}
{$DEFINE dx_has_Inline}
{$DEFINE dx_has_LpVoid}
{$DEFINE dx_has_VclThemes}
{$DEFINE dx_midstr_in_AnsiStrings}
{$endif}
{$ifdef VER310}
// Delphi 10.1 Berlin
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_StringList_has_OwnsObjects}
{$DEFINE dx_GetStrProp_reads_unicode}
{$DEFINE dx_has_Inline}
{$DEFINE dx_has_LpVoid}
{$DEFINE dx_has_VclThemes}
{$DEFINE dx_midstr_in_AnsiStrings}
{$endif}
{$ifdef VER320}
// Delphi 10.2 Tokyo
{$DEFINE dx_has_Unsafe_Warnings}
{$DEFINE dx_has_WideStrings}
{$DEFINE dx_StringList_has_OwnsObjects}
{$DEFINE dx_GetStrProp_reads_unicode}
{$DEFINE dx_has_Inline}
{$DEFINE dx_has_LpVoid}
{$DEFINE dx_has_VclThemes}
{$DEFINE dx_midstr_in_AnsiStrings}
{$endif}
{$ifdef dx_has_Unsafe_Warnings}
{$WARN UNSAFE_TYPE OFF}
{$WARN UNSAFE_CODE OFF}
{$WARN UNSAFE_CAST OFF}
{$endif dx_has_Unsafe_Warnings}
uses
{$ifdef MSWINDOWS}
Windows,
{$else}
Libc,
{$ifdef FPC}
CWString,
{$endif}
{$endif}
{$IFDEF dx_midstr_in_AnsiStrings}
System.AnsiStrings,
{$ENDIF dx_midstr_in_AnsiStrings}
{$IFDEF dx_has_WideStrings}
WideStrings,
{$ENDIF dx_has_WideStrings}
Types, Classes, StrUtils, SysUtils, TypInfo;
(*****************************************************************************)
(* *)
(* MAIN API *)
(* *)
(*****************************************************************************)
type
{$IFNDEF UNICODE}
UnicodeString=WideString;
RawUtf8String=AnsiString;
RawByteString=AnsiString;
{$ELSE}
RawUtf8String=RawByteString;
{$ENDIF}
DomainString=string;
LanguageString=string;
ComponentNameString=string;
FilenameString=string;
MsgIdString=UnicodeString;
TranslatedUnicodeString=UnicodeString;
// Main GNU gettext functions. See documentation for instructions on how to use them.
function _(const szMsgId: MsgIdString): TranslatedUnicodeString;
function gettext(const szMsgId: MsgIdString): TranslatedUnicodeString;
function gettext_NoExtract(const szMsgId: MsgIdString): TranslatedUnicodeString;
function gettext_NoOp(const szMsgId: MsgIdString): TranslatedUnicodeString;
function dgettext(const szDomain: DomainString; const szMsgId: MsgIdString): TranslatedUnicodeString;
function dgettext_NoExtract(const szDomain: DomainString; const szMsgId: MsgIdString): TranslatedUnicodeString;
function dgettext_NoOp(const szDomain: DomainString; const szMsgId: MsgIdString): TranslatedUnicodeString;
function dngettext(const szDomain: DomainString; const singular,plural: MsgIdString; Number:longint): TranslatedUnicodeString;
function ngettext(const singular,plural: MsgIdString; Number:longint): TranslatedUnicodeString;
function ngettext_NoExtract(const singular,plural: MsgIdString; Number:longint): TranslatedUnicodeString;
function pgettext(const szMsgCtxt,szMsgId: MsgIdString): TranslatedUnicodeString;
function pdgettext(const szDomain: DomainString; const szMsgCtxt,szMsgId: MsgIdString): TranslatedUnicodeString;
function pngettext(const szMsgCtxt,singular,plural: MsgIdString; Number:longint): TranslatedUnicodeString;
function pdngettext(const szDomain: DomainString; const szMsgCtxt,singular,plural: MsgIdString; Number:longint): TranslatedUnicodeString;
procedure textdomain(const szDomain: DomainString);
function getcurrenttextdomain: DomainString;
procedure bindtextdomain(const szDomain: DomainString; const szDirectory: FilenameString);
// Set language to use
procedure UseLanguage(LanguageCode: LanguageString);
function GetCurrentLanguage:LanguageString;
// Translates a component (form, frame etc.) to the currently selected language.
// Put TranslateComponent(self) in the OnCreate event of all your forms.
// See the manual for documentation on these functions
type
TTranslator=procedure (obj:TObject) of object;
procedure TP_Ignore(AnObject:TObject; const name:ComponentNameString);
procedure TP_IgnoreClass (IgnClass:TClass);
procedure TP_IgnoreClassProperty (IgnClass:TClass;const propertyname:ComponentNameString);
procedure TP_GlobalIgnoreClass (IgnClass:TClass);
function TP_TryGlobalIgnoreClass (IgnClass:TClass): boolean;
procedure TP_GlobalIgnoreClassProperty (IgnClass:TClass;const propertyname:ComponentNameString);
procedure TP_GlobalHandleClass (HClass:TClass;Handler:TTranslator);
procedure TP_Remember(AnObject: TObject; PropName:ComponentNameString; OldValue:TranslatedUnicodeString);
procedure TranslateComponent(AnObject: TComponent; const TextDomain:DomainString='');
procedure RetranslateComponent(AnObject: TComponent; const TextDomain:DomainString='');
// Add more domains that resourcestrings can be extracted from. If a translation
// is not found in the default domain, this domain will be searched, too.
// This is useful for adding mo files for certain runtime libraries and 3rd
// party component libraries
procedure AddDomainForResourceString (const domain:DomainString);
procedure RemoveDomainForResourceString (const domain:DomainString);
// Add more domains that component strings can be extracted from. If a translation
// is not found in the default domain, this domain will be searched, too.
// This is useful when an application inherits components from a 3rd
// party component libraries
procedure AddDomainForComponent (const domain:DomainString);
procedure RemoveDomainForComponent (const domain:DomainString);
// Unicode-enabled way to get resourcestrings, automatically translated
// Use like this: ws:=LoadResStringW(@NameOfResourceString);
function LoadResString(ResStringRec: PResStringRec): widestring;
function LoadResStringW(ResStringRec: PResStringRec): UnicodeString;
function PLoadResString(const szMsgCtxt: MsgIdString; ResStringRec: PResStringRec): widestring;
function PLoadResStringW(const szMsgCtxt: MsgIdString; ResStringRec: PResStringRec): UnicodeString;
// This returns an empty string if not translated or translator name is not specified.
function GetTranslatorNameAndEmail:TranslatedUnicodeString;
(*****************************************************************************)
(* *)
(* ADVANCED FUNCTIONALITY *)
(* *)
(*****************************************************************************)
const
DefaultTextDomain = 'default';
var
ExecutableFilename: FilenameString; // This is set to paramstr(0) or the name of the DLL you are creating.
const
PreferExternal = False; // Set to true, to prefer external *.mo over embedded translation
UseMemoryMappedFiles = True; // Set to False, to use the mo-file as independent copy in memory (you can update the file while it is in use)
ReReadMoFileOnSameLanguage = False; // Set to True, to reread mo-file if the current language is selected again
const
// Subversion source code version control version information
VCSVersion='$LastChangedRevision: 220 $';
type
EGnuGettext=class(Exception);
EGGProgrammingError=class(EGnuGettext);
EGGComponentError=class(EGnuGettext);
EGGIOError=class(EGnuGettext);
EGGAnsi2WideConvError=class(EGnuGettext);
// This function will turn resourcestring hooks on or off, eventually with BPL file support.
// Please do not activate BPL file support when the package is in design mode.
const AutoCreateHooks=true;
procedure HookIntoResourceStrings (enabled:boolean=true; SupportPackages:boolean=false);
(*****************************************************************************)
(* *)
(* CLASS based implementation. *)
(* Use TGnuGettextInstance to have more than one language *)
(* in your application at the same time *)
(* *)
(*****************************************************************************)
type
TOnDebugLine = Procedure (Sender: TObject; const Line: String; var Discard: Boolean) of Object; // Set Discard to false if output should still go to ordinary debug log
TGetPluralForm=function (Number:Longint):Integer;
TDebugLogger=procedure (line: string) of object;
{*------------------------------------------------------------------------------
Handles .mo files, in separate files or inside the exe file.
Don't use this class. It's for internal use.
-------------------------------------------------------------------------------}
TMoFile=
class /// Threadsafe. Only constructor and destructor are writing to memory
private
doswap: boolean;
public
Users:Integer; /// Reference count. If it reaches zero, this object should be destroyed.
constructor Create (const filename: FilenameString;
const Offset: int64; Size: int64;
const xUseMemoryMappedFiles: Boolean;
const ResName: string);
destructor Destroy; override;
function gettext(const msgid: RawUtf8String;var found:boolean): RawUtf8String; // uses mo file and utf-8
property isSwappedArchitecture:boolean read doswap;
private
N, O, T: Cardinal; /// Values defined at http://www.linuxselfhelp.com/gnu/gettext/html_chapter/gettext_6.html
startindex,startstep:integer;
FUseMemoryMappedFiles: Boolean;
mo: THandle;
momapping: THandle;
momemoryHandle:PAnsiChar;
momemory: PAnsiChar;
function autoswap32(i: cardinal): cardinal;
function CardinalInMem(baseptr: PAnsiChar; Offset: Cardinal): Cardinal;
end;
{*------------------------------------------------------------------------------
Handles all issues regarding a specific domain.
Don't use this class. It's for internal use.
-------------------------------------------------------------------------------}
TDomain=
class
private
Enabled:boolean;
vDirectory: FilenameString;
procedure setDirectory(const dir: FilenameString);
public
DebugLogger:TDebugLogger;
Domain: DomainString;
property Directory: FilenameString read vDirectory write setDirectory;
constructor Create;
destructor Destroy; override;
// Set parameters
procedure SetLanguageCode (const langcode:LanguageString);
procedure SetFilename (const filename:FilenameString); // Bind this domain to a specific file
// Get information
procedure GetListOfLanguages(list:TStrings);
function GetTranslationProperty(Propertyname: ComponentNameString): TranslatedUnicodeString;
function gettext(const msgid: RawUtf8String): RawUtf8String; // uses mo file and utf-8
private
mofile:TMoFile;
SpecificFilename:FilenameString;
curlang: LanguageString;
OpenHasFailedBefore: boolean;
procedure OpenMoFile;
procedure CloseMoFile;
end;
{*------------------------------------------------------------------------------
Helper class for invoking events.
-------------------------------------------------------------------------------}
TExecutable=
class
procedure Execute; virtual; abstract;
end;
{*------------------------------------------------------------------------------
Interface to implement if you want to register as a language change listener
-------------------------------------------------------------------------------}
IGnuGettextInstanceWhenNewLanguageListener = interface
procedure WhenNewLanguage (const LanguageID:LanguageString);
end;
{*------------------------------------------------------------------------------
The main translation engine.
-------------------------------------------------------------------------------}
TGnuGettextInstance=
class
private
fOnDebugLine:TOnDebugLine;
public
Enabled:Boolean; /// Set this to false to disable translations
DesignTimeCodePage:Integer; /// See MultiByteToWideChar() in Win32 API for documentation
SearchAllDomains: Boolean; /// Should gettext and ngettext look in all other known domains after the current one
constructor Create;
destructor Destroy; override;
procedure UseLanguage(LanguageCode: LanguageString);
procedure GetListOfLanguages (const domain:DomainString; list:TStrings); // Puts list of language codes, for which there are translations in the specified domain, into list
{$ifndef UNICODE}
function gettext(const szMsgId: ansistring): TranslatedUnicodeString; overload; virtual;
function ngettext(const singular,plural:ansistring;Number:longint):TranslatedUnicodeString; overload; virtual;
{$endif}
function gettext(const szMsgId: MsgIdString): TranslatedUnicodeString; overload; virtual;
function gettext_NoExtract(const szMsgId: MsgIdString): TranslatedUnicodeString;
function gettext_NoOp(const szMsgId: MsgIdString): TranslatedUnicodeString;
function ngettext(const singular,plural:MsgIdString;Number:longint):TranslatedUnicodeString; overload; virtual;
function ngettext_NoExtract(const singular,plural:MsgIdString;Number:longint):TranslatedUnicodeString;
function GetCurrentLanguage:LanguageString;
function GetTranslationProperty (const Propertyname:ComponentNameString):TranslatedUnicodeString;
function GetTranslatorNameAndEmail:TranslatedUnicodeString;
// Form translation tools, these are not threadsafe. All TP_ procs must be called just before TranslateProperites()
procedure TP_Ignore(AnObject:TObject; const name:ComponentNameString);
procedure TP_IgnoreClass (IgnClass:TClass);
procedure TP_IgnoreClassProperty (IgnClass:TClass;propertyname:ComponentNameString);
function TP_TryGlobalIgnoreClass (IgnClass:TClass): boolean;
procedure TP_GlobalIgnoreClass (IgnClass:TClass);
procedure TP_GlobalIgnoreClassProperty (IgnClass:TClass;propertyname:ComponentNameString);
procedure TP_GlobalHandleClass (HClass:TClass;Handler:TTranslator);
procedure TP_Remember(AnObject: TObject; PropName:ComponentNameString; OldValue:TranslatedUnicodeString);
procedure TranslateProperties(AnObject: TObject; textdomain:DomainString='');
procedure TranslateComponent(AnObject: TComponent; const TextDomain:DomainString='');
procedure RetranslateComponent(AnObject: TComponent; const TextDomain:DomainString='');
// Multi-domain functions
{$ifndef UNICODE}
function dgettext(const szDomain: DomainString; const szMsgId: ansistring): TranslatedUnicodeString; overload; virtual;
function dngettext(const szDomain: DomainString; const singular,plural:ansistring;Number:longint):TranslatedUnicodeString; overload; virtual;
{$endif}
function dgettext(const szDomain: DomainString; const szMsgId: MsgIdString): TranslatedUnicodeString; overload; virtual;
function dgettext_NoExtract(const szDomain: DomainString; const szMsgId: MsgIdString): TranslatedUnicodeString;
function dgettext_NoOp(const szDomain: DomainString; const szMsgId: MsgIdString): TranslatedUnicodeString;
function dngettext(const szDomain: DomainString; const singular,plural:MsgIdString;Number:longint):TranslatedUnicodeString; overload; virtual;
function dngettext_NoExtract(const szDomain: DomainString; const singular,plural:MsgIdString;Number:longint):TranslatedUnicodeString;
procedure textdomain(const szDomain: DomainString);
function getcurrenttextdomain: DomainString;
procedure bindtextdomain(const szDomain: DomainString; const szDirectory: FilenameString);
procedure bindtextdomainToFile (const szDomain: DomainString; const filename: FilenameString); // Also works with files embedded in exe file
// particular translations (context parameter)
function pgettext(const szMsgCtxt,szMsgId: MsgIdString): TranslatedUnicodeString;
function pdgettext(const szDomain: DomainString; const szMsgCtxt,szMsgId: MsgIdString): TranslatedUnicodeString;
function pngettext(const szMsgCtxt,singular,plural: MsgIdString; Number:longint): TranslatedUnicodeString;
function pdngettext(const szDomain: DomainString; const szMsgCtxt,singular,plural: MsgIdString; Number:longint): TranslatedUnicodeString;
// Windows API functions
function LoadResString(ResStringRec: PResStringRec): UnicodeString;
function PLoadResString(const szMsgCtxt: MsgIdString; ResStringRec: PResStringRec): UnicodeString;
// Output all log info to this file. This may only be called once.
procedure DebugLogToFile (const filename:FilenameString; append:boolean=false);
procedure DebugLogPause (PauseEnabled:boolean);
property OnDebugLine: TOnDebugLine read fOnDebugLine write fOnDebugLine; // If set, all debug output goes here
{$ifndef UNICODE}
// Conversion according to design-time character set
function ansi2wideDTCP (const s:AnsiString):MsgIdString; // Convert using Design Time Code Page
{$endif}
procedure RegisterWhenNewLanguageListener(Listener: IGnuGettextInstanceWhenNewLanguageListener);
procedure UnregisterWhenNewLanguageListener(Listener: IGnuGettextInstanceWhenNewLanguageListener);
protected
procedure TranslateStrings (sl:TStrings;const TextDomain:DomainString);
{$IFDEF dx_has_WideStrings}
procedure TranslateWideStrings (sl: TWideStrings;const TextDomain:DomainString);
{$ENDIF dx_has_WideStrings}
// Override these three, if you want to inherited from this class
// to create a new class that handles other domain and language dependent
// issues
procedure WhenNewLanguage (const LanguageID:LanguageString); virtual; // Override to know when language changes
procedure WhenNewDomain (const TextDomain:DomainString); virtual; // Override to know when text domain changes. Directory is purely informational
procedure WhenNewDomainDirectory (const TextDomain:DomainString;const Directory:FilenameString); virtual; // Override to know when any text domain's directory changes. It won't be called if a domain is fixed to a specific file.
private
curlang: LanguageString;
curGetPluralForm:TGetPluralForm;
curmsgdomain: DomainString;
savefileCS: TMultiReadExclusiveWriteSynchronizer;
savefile: TextFile;
savememory: TStringList;
DefaultDomainDirectory:FilenameString;
domainlist: TStringList; /// List of domain names. Objects are TDomain.
TP_IgnoreList:TStringList; /// Temporary list, reset each time TranslateProperties is called
TP_ClassHandling:TList; /// Items are TClassMode. If a is derived from b, a comes first
TP_GlobalClassHandling:TList; /// Items are TClassMode. If a is derived from b, a comes first
TP_Retranslator:TExecutable; /// Cast this to TTP_Retranslator
fWhenNewLanguageListeners: TInterfaceList; /// List of all registered WhenNewLanguage listeners
{$ifdef DXGETTEXTDEBUG}
DebugLogCS:TMultiReadExclusiveWriteSynchronizer;
DebugLog:TStream;
DebugLogOutputPaused:Boolean;
{$endif}
function TP_CreateRetranslator:TExecutable; // Must be freed by caller!
procedure FreeTP_ClassHandlingItems;
function ClassIsIgnored(AClass:TClass): Boolean;
{$ifdef DXGETTEXTDEBUG}
procedure DebugWriteln(Line: string);
{$endif}
procedure TranslateProperty(AnObject: TObject; PropInfo: PPropInfo;
TodoList: TStrings; const TextDomain:DomainString);
function Getdomain(const domain:DomainString; const DefaultDomainDirectory:FilenameString; const CurLang: LanguageString): TDomain; // Translates a single property of an object
function GetResString(ResStringRec: PResStringRec): UnicodeString;
procedure pgettext_fixup(const szLookup,szMsgId: MsgIdString; var szTranslation: MsgIdString); {$ifdef dx_has_Inline}inline;{$endif}
end;
const
LOCALE_SISO639LANGNAME = $59; // Used by Lazarus software development tool
LOCALE_SISO3166CTRYNAME = $5A; // Used by Lazarus software development tool
GETTEXT_CONTEXT_GLUE = #4;
var
DefaultInstance:TGnuGettextInstance; /// Default instance of the main API for singlethreaded applications.
implementation
{$ifdef dx_has_VclThemes}
uses
Vcl.Themes;
{$endif dx_has_VclThemes}
{$ifndef MSWINDOWS}
{$ifndef LINUX}
'This version of gnugettext.pas is only meant to be compiled with Kylix 3,'
'Delphi 6, Delphi 7 and later versions. If you use other versions, please'
'get the gnugettext.pas version from the Delphi 5 directory.'
{$endif}
{$endif}
{$ifdef dx_NativeUInt_is_Cardinal}
type
NativeUInt = cardinal;
{$endif}
(**************************************************************************)
// Some comments on the implementation:
// This unit should be independent of other units where possible.
// It should have a small footprint in any way.
(**************************************************************************)
// TMultiReadExclusiveWriteSynchronizer is used instead of TCriticalSection
// because it makes this unit independent of the SyncObjs unit
(**************************************************************************)
{$B-,R+,I+,Q+}
type
TTP_RetranslatorItem=
class
obj:TObject;
Propname:ComponentNameString;
OldValue:TranslatedUnicodeString;
end;
TTP_Retranslator=
class (TExecutable)
TextDomain:DomainString;
Instance:TGnuGettextInstance;
constructor Create;
destructor Destroy; override;
procedure Remember (obj:TObject; PropName:ComponentNameString; OldValue:TranslatedUnicodeString);
procedure Execute; override;
private
list:TList;
end;
TEmbeddedFileInfo=
class
offset,size:int64;
end;
{$IFDEF dx_SupportsResources}
TResourceFileInfo = class
public
ResourceName: string;
constructor Create(const _ResourceName: string);
end;
{$ENDIF dx_SupportsResources}
TFileLocator=
class // This class finds files even when embedded inside executable
constructor Create;
destructor Destroy; override;
function FindSignaturePos(const signature: RawByteString; str: TFileStream): Int64;
procedure Analyze; // List files embedded inside executable
function FileExists (filename:FilenameString):boolean;
function GetMoFile (filename:FilenameString;DebugLogger:TDebugLogger):TMoFile;
procedure ReleaseMoFile (mofile:TMoFile);
private
basedirectory:FilenameString;
filelist:TStringList; //Objects are TEmbeddedFileInfo. Filenames are relative to .exe file
{$IFDEF dx_SupportsResources}
FResourceList: TStringList; // Objects are TResourceFileInfo, Filenames are relative to .exe file
{$ENDIF dx_SupportsResources}
MoFilesCS:TMultiReadExclusiveWriteSynchronizer;
MoFiles:TStringList; // Objects are filenames+offset, objects are TMoFile
function ReadInt64 (str:TStream):int64;
end;
TGnuGettextComponentMarker=
class (TComponent)
public
LastLanguage:LanguageString;
Retranslator:TExecutable;
destructor Destroy; override;
end;
TClassMode=
class
HClass:TClass;
SpecialHandler:TTranslator;
PropertiesToIgnore:TStringList; // This is ignored if Handler is set
constructor Create;
destructor Destroy; override;
end;
TRStrinfo = record
strlength, stroffset: cardinal;
end;
TStrInfoArr = array[0..10000000] of TRStrinfo;
PStrInfoArr = ^TStrInfoArr;
TCharArray5=array[0..4] of ansichar;
THook= // Replaces a runtime library procedure with a custom procedure
class
public
constructor Create (OldProcedure, NewProcedure: pointer; FollowJump:boolean=false);
destructor Destroy; override; // Restores unhooked state
procedure Reset (FollowJump:boolean=false); // Disables and picks up patch points again
procedure Disable;
procedure Enable;
private
oldproc,newproc:Pointer;
Patch:TCharArray5;
Original:TCharArray5;
PatchPosition:PAnsiChar;
procedure Shutdown; // Same as destroy, except that object is not destroyed
end;
PProxyClassData = ^TProxyClassData;
TProxyClassData = record
SelfPtr: TClass;
IntfTable: Pointer;
AutoTable: Pointer;
InitTable: Pointer;
TypeInfo: PTypeInfo;
FieldTable: Pointer;
MethodTable: Pointer;
DynamicTable: Pointer;
ClassName: PShortString;
InstanceSize: Integer;
Parent: ^TClass;
end;
THookedObjects=
class(TList)
private
interceptorClassDatas:TList;
function findInterceptorClassData(aClass:TClass):Pointer;
procedure BeforeDestructionHook;
function GetBeforeDestructionHookAddress: Pointer;
public
constructor Create;
destructor Destroy; override;
procedure Proxify(obj:TObject);
procedure Unproxify(obj:TObject);
end;
var
// System information
Win32PlatformIsUnicode:boolean=False;
// Information about files embedded inside .exe file
FileLocator:TFileLocator;
// Hooks into runtime library functions
ResourceStringDomainListCS:TMultiReadExclusiveWriteSynchronizer;
ResourceStringDomainList:TStringList;
ComponentDomainListCS:TMultiReadExclusiveWriteSynchronizer;
ComponentDomainList:TStringList;
HookLoadResString:THook;
HookLoadStr:THook;
HookFmtLoadStr:THook;
HookedObjects:THookedObjects;
KnownRetranslators:TList;
function GGGetEnvironmentVariable(const Name:widestring):widestring;
var
Len: integer;
W : WideString;
begin
Result := '';
SetLength(W,1);
Len := Windows.GetEnvironmentVariableW(PWideChar(Name), PWideChar(W), 1);
if Len > 0 then begin
SetLength(Result, Len - 1);
Windows.GetEnvironmentVariableW(PWideChar(Name), PWideChar(Result), Len);
end;
end;
function StripCRRawMsgId (s:RawUtf8String):RawUtf8String;
var
i:integer;
begin
i:=1;
while i<=length(s) do begin
if s[i]=#13 then delete (s,i,1) else inc (i);
end;
Result:=s;
end;
{$ifdef dx_midstr_in_AnsiStrings}
function MidStr(const AText: RawUtf8String; const AStart, ACount: Integer): RawUtf8String; overload; inline;
begin
Result := System.AnsiStrings.MidStr(AText, AStart, ACount);
end;
{$endif dx_midstr_in_AnsiStrings}
function EnsureLineBreakInTranslatedString (s:RawUtf8String):RawUtf8String;
{$ifdef MSWINDOWS}
var
i:integer;
{$endif}
begin
{$ifdef MSWINDOWS}
Assert (sLinebreak=ansistring(#13#10));
i:=1;
while i<=length(s) do begin
if (s[i]=#10) and (MidStr(s,i-1,1)<>#13) then begin
insert (#13,s,i);
inc (i,2);
end else
inc (i);
end;
{$endif}
Result:=s;
end;
function IsWriteProp(Info: PPropInfo): Boolean;
begin
Result := Assigned(Info) and (Info^.SetProc <> nil);
end;
function ResourceStringGettext(MsgId: MsgIdString): TranslatedUnicodeString;
var
i:integer;
begin
if (MsgID='') or (ResourceStringDomainListCS=nil) then begin
// This only happens during very complicated program startups that fail,
// or when Msgid=''
Result:=MsgId;
exit;
end;
ResourceStringDomainListCS.BeginRead;
try
for i:=0 to ResourceStringDomainList.Count-1 do begin
Result:=dgettext(ResourceStringDomainList.Strings[i], MsgId);
if Result<>MsgId then
break;
end;
finally
ResourceStringDomainListCS.EndRead;
end;
end;
function ComponentGettext(MsgId: MsgIdString; Instance: TGnuGettextInstance = nil): TranslatedUnicodeString;
var
i:integer;
begin
if (MsgID='') or (ComponentDomainListCS=nil) then begin
// This only happens during very complicated program startups that fail,
// or when Msgid=''
Result:=MsgId;
exit;
end;
// First, get the value from the default domain
if Assigned(Instance) then
Result:=Instance.dgettext(Instance.curmsgdomain, MsgId)
else
Result:=dgettext(DefaultInstance.curmsgdomain, MsgId);
if Result<>MsgId then
exit;
// If it was not in the default domain, then go through the others
ComponentDomainListCS.BeginRead;
try
for i:=0 to ComponentDomainList.Count-1 do begin
if Assigned(Instance) then
Result:=Instance.dgettext(ComponentDomainList.Strings[i], MsgId)
else
Result:=dgettext(ComponentDomainList.Strings[i], MsgId);
if Result<>MsgId then
break;
end;
finally
ComponentDomainListCS.EndRead;
end;
end;
function gettext(const szMsgId: MsgIdString): TranslatedUnicodeString;
begin
Result := DefaultInstance.gettext(szMsgId);
end;
function gettext_NoExtract(const szMsgId: MsgIdString): TranslatedUnicodeString;
begin
// This one is very useful for translating text in variables.
// This can sometimes be necessary, and by using this function,
// the source code scanner will not trigger warnings.
Result := gettext(szMsgId);
end;
function gettext_NoOp(const szMsgId: MsgIdString): TranslatedUnicodeString;
begin
//*** With this function Strings can be added to the po-file without beeing
// ResourceStrings (dxgettext will add the string and this function will
// return it without a change)
// see gettext manual
// 4.7 - Special Cases of Translatable Strings
// http://www.gnu.org/software/hello/manual/gettext/Special-cases.html#Special-cases
Result := DefaultInstance.gettext_NoOp(szMsgId);
end;
{*------------------------------------------------------------------------------
This is the main translation procedure used in programs. It takes a parameter,
looks it up in the translation dictionary, and returns the translation.
If no translation is found, the parameter is returned.
@param szMsgId The text, that should be displayed if no translation is found.
-------------------------------------------------------------------------------}
function _(const szMsgId: MsgIdString): TranslatedUnicodeString;
begin
Result:=DefaultInstance.gettext(szMsgId);
end;
{*------------------------------------------------------------------------------
Translates a text, using a specified translation domain.
If no translation is found, the parameter is returned.
@param szDomain Which translation domain that should be searched for a translation.
@param szMsgId The text, that should be displayed if no translation is found.
-------------------------------------------------------------------------------}
function dgettext(const szDomain: DomainString; const szMsgId: MsgIdString): TranslatedUnicodeString;
begin
Result:=DefaultInstance.dgettext(szDomain, szMsgId);
end;
function dgettext_NoExtract(const szDomain: DomainString; const szMsgId: MsgIdString): TranslatedUnicodeString;
begin
// This one is very useful for translating text in variables.
// This can sometimes be necessary, and by using this function,
// the source code scanner will not trigger warnings.
Result := dgettext(szDomain, szMsgId);
end;
function dgettext_NoOp(const szDomain: DomainString; const szMsgId: MsgIdString): TranslatedUnicodeString;
begin
//*** With this function Strings can be added to the po-file without beeing
// ResourceStrings (dxgettext will add the string and this function will
// return it without a change)
// see gettext manual
// 4.7 - Special Cases of Translatable Strings
// http://www.gnu.org/software/hello/manual/gettext/Special-cases.html#Special-cases
Result := DefaultInstance.dgettext_NoOp(szDomain, szMsgId);
end;
function dngettext(const szDomain: DomainString; const singular,plural: MsgIdString; Number:longint): TranslatedUnicodeString;
begin
Result:=DefaultInstance.dngettext(szDomain,singular,plural,Number);
end;
function ngettext(const singular,plural: MsgIdString; Number:longint): TranslatedUnicodeString;
begin
Result:=DefaultInstance.ngettext(singular,plural,Number);
end;
function ngettext_NoExtract(const singular,plural: MsgIdString; Number:longint): TranslatedUnicodeString;
begin
// This one is very useful for translating text in variables.
// This can sometimes be necessary, and by using this function,
// the source code scanner will not trigger warnings.
Result := ngettext(singular, plural, Number);