configure.in

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ([2.64])
AC_INIT([salfet], [0.1.0], [http://github.com/Kojoley/salfet/issues])
AC_CONFIG_SRCDIR([salfet.c])
AC_CONFIG_HEADERS([config.h])

# Checks for programs.
AC_PROG_CC_C99
PKG_PROG_PKG_CONFIG([0.20])

AC_ARG_ENABLE([static-link],
	AS_HELP_STRING([--enable-static-link], [Link statically with libraries [no]]),
	[ enable_static_link=${enableval} ], [ enable_static_link=no ])
if test "x$enable_static_link" = "xyes" ; then
	# Tell pkg-config to link against static libraries, incl. all dependencies
	PKG_CONFIG+=" --static"
fi

AC_ARG_ENABLE([static],
	AS_HELP_STRING([--enable-static], [Link statically [no]]),
	[ enable_static=${enableval} ], [ enable_static=no ])
if test "x$enable_static" = "xyes" ; then
	CFLAGS+=" --static"
	LDFLAGS+=" --static"
fi

AC_ARG_ENABLE([static-link],
	AS_HELP_STRING([--enable-static-link], [Link statically with libraries [no]]),
	[ enable_static_link=${enableval} ], [ enable_static_link=no ])

AC_ARG_VAR(FFMPEG_PATH, [path to FFmpeg])

# Checks for header files.
AC_CHECK_HEADERS([inttypes.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
AC_TYPE_INT64_T
AC_TYPE_UINT8_T

# Check if path to FFmpeg was supplied
if test -n "$FFMPEG_PATH"; then
	AC_MSG_CHECKING([custom FFmpeg path])
	if test -d "$FFMPEG_PATH"; then
		AC_MSG_RESULT([exists])
		AC_MSG_CHECKING([for .pc files])
		FFMPEG_CUSTOM_PATH="$FFMPEG_PATH/doc/examples/pc-uninstalled"
		if test -d "$FFMPEG_CUSTOM_PATH"; then
			# Easy way, works in latest FFmpeg. It have nice pc-uninstalled
			export PKG_CONFIG_PATH="$FFMPEG_CUSTOM_PATH:$PKG_CONFIG_PATH"
			export PKG_CONFIG_LIBDIR="$FFMPEG_CUSTOM_PATH:$PKG_CONFIG_LIBDIR"
		else
			# Hard way, for older FFmpeg. Search pc files in FFmpeg dir
			FFMPEG_CUSTOM_PATH=`find "$FFMPEG_PATH" -mindepth 2 -maxdepth 2 | grep uninstalled.pc$ | xargs -L1 dirname | tr '\n' ':'`
			if test -n "$FFMPEG_CUSTOM_PATH"; then
				export PKG_CONFIG_PATH="$FFMPEG_CUSTOM_PATH:$PKG_CONFIG_PATH"
				export PKG_CONFIG_LIBDIR="$FFMPEG_CUSTOM_PATH:$PKG_CONFIG_LIBDIR"
				# Because of strange pc-uninstalled files content
				m4_pattern_allow([^PKG_CONFIG_DISABLE_UNINSTALLED$])
				export PKG_CONFIG_DISABLE_UNINSTALLED=1
				CFLAGS+=" -I$FFMPEG_PATH"
				LDFLAGS+=`find "$FFMPEG_PATH" -mindepth 2 -maxdepth 2 | grep uninstalled.pc$ | xargs -L1 dirname | sed 's/^/ -L/' | tr -d '\n'`
			else
				AC_MSG_RESULT([could not locate])
				AC_MSG_FAILURE([Build FFmpeg first! If already, please send bug report])
			fi
		fi
		AC_MSG_RESULT([found])
	else
		AC_MSG_RESULT([is not directory])
		AC_MSG_ERROR([Provide correct path to FFmpeg])
	fi
fi

# Checks for libraries.
PKG_CHECK_MODULES([FFMPEG], [libavformat >= 53.17.0 libavcodec >= 53.34.0 libswscale >= 0.9.0 libavutil >= 51.12.0])

# Checks for library functions.

AC_CONFIG_FILES([Makefile])
AC_OUTPUT